Martin's program works in Mode 2 but not not quite in Mode 3

'only for RP2350 assembler. this does not work on RP2040

pio clear 1

pio assemble 1,".program test"
pio assemble 1,".line 0"
pio assemble 1,"set y,4"            'just a value 4 in Y
pio assemble 1,"mov isr,y"          'copy Y to isr
pio assemble 1,"jmp y--,next"       'y=y-1 always to next
pio assemble 1,"next:"
pio assemble 1,"mov rxfifo[y],isr"  'should program 4 in fifo [3]
pio assemble 1,"mov isr,y"          'copy Y to isr
pio assemble 1,"mov rxfifo[2],isr"  'should program 3 in fifo [2]
pio assemble 1,"jmp 0"              'repeat
pio assemble 1,".end program"
'pio assemble 1,".end program list"

f=1e6 '1MHz

'PIO(EXECCTRL a,b,c)
'a/ the GPIO pin for conditional JMP (e.g. GP0)
'b/ the WRAP TARGET line number(e.g. 1)
'c/ the WRAP line number(e.g. 2)
e=pio(execctrl gp0,0,31)  'default value, not actually changed

'PIO(SHIFTCTRL a,b,c,d,e,f,g,h,i,j)
'a/ push threshold (leave 0 for now)
'b/ pull threshold (leave 0 for now)
'c/ autopush (leave 0 for now)
'd/ autopull (leave 0 for now)
'e/ IN-shiftdir (1 = shift MSB, 0 = shift LSB)
'f/ OUT-shiftdir (1 = shift MSB, 0 = shift LSB)
'g/ fjoin_rx (join TX and RX fifo to 1 RX fifo)
'h/ fjoin_tx (join TX and RX fifo to 1 TX fifo)
'i/ FJOIN_RX_GET, when 1 ARM can write individual RX FIFO registers
'j/ FJOIN_RX_PUT, when 1 ARM can read individual RX FIFO registers
sr=pio(shiftctrl 0,0,0,0,0,0,0,0,0,1) 'read individual RX, RX=3 deep
sw=pio(shiftctrl 0,0,0,0,0,0,0,0,1,0) 'write individual RX, RX=3 deep

'PIO(PINCTRL a,b,c,d,e,f,g)
'a/ the number of SIDE SET pins (0...5), SIDE SET can write 5 pins at once
'b/ the number of SET pins (0...5), SET can write 5 pins at once
'c/ the number of OUT pins (0...31), OUT can write 32 pins at once
'd/ the lowest pin for IN pins (GP0.....GP31) IN can read up to 32 pins at once
'e/ the lowest pin for SIDE SET (GP0.....GP31)
'f/ the lowest pin for SET (GP0.....GP31)
'g/ the lowest pin for OUT (GP0.....GP31)
p=pio(pinctrl 0,0,0,gp0,gp0,gp0,gp0) 'defaultvalue , not actually changed


'the test sequence

'clear the fifo
pio init machine 1,0,f,p,e,sw,0     'init machine for writing to RX fifo
for i=0 to &h3  'write the 4 RXFIFO registers
 pio writefifo 1,0,i,&h100*(i+1) 'write a value
next

'verify clear
print "3 RXFIFO registers before running the program"
pio init machine 1,0,f,p,e,sr,0    'init machine for reading the RX fifo
for i=0 to 3   'read the 4 RXFIFO registers
   print i,hex$(pio(readfifo 1,0,i)) 'verify they are 0
next
print

'now we run the PIO program. That should (continuously) write to reg 2 and 3
pio start 1,0

'verify writes
print "3 RXFIFO registers after running the program"
for i=0 to 3   'read the 4 FIFO registers to see if the program works
   print i,hex$(pio(readfifo 1,0,i))
next