'Sine wave generator 1Hz...1MHz using a ladder DAC on Picomite 5.07.08b7 and newer
'amplitude resolution defined in variable "bits%". In demo this is 7 bits on GP6...GP12
'uses PIO to output pre-calculated data through ring buffer DMA.
'this version uses 5.070807 that has continuous DMA.

'has options to use FIFO more efficient for 8 bit.

'defines
bits% = 7 '7 bit ladder DAC
length% = 4096          'allows up to 16kHz full resolution
Dim o%(length%-1) 'array containing source samples
level=2^(bits%-1)*0.9   'amplitude of sine signal is 90%


'packed data in DMA ring buffer
Dim pkd%
'PIO make ring buffer pkd%,length%*4  'length in 32 bit fifo values
PIO make ring buffer pkd%,length%     'length in 8 bit fifo values

'free pio pins for use with ladder DAC
SetPin gp6,pio1
SetPin gp7,pio1
SetPin gp8,pio1
SetPin gp9,pio1
SetPin gp10,pio1
SetPin gp11,pio1
SetPin gp12,pio1

'pio program to send 4x8bit values packed in 32 bits to GPx pins, or 32 bits.
PIO assemble 1,".program out"
PIO assemble 1,".line 0"
PIO assemble 1,"mov osr ,!null" 'fill osr with &hffffffff
PIO assemble 1,"out pindirs,8"  'set all associated pins (8) output
PIO assemble 1,".wrap target"
PIO assemble 1,"pull noblock"   'get data from fifo
PIO assemble 1,"out pins,8"     'write out to 7(8) pins
PIO assemble 1,"out pins,8 [1]" 'write out to 7(8) pins delay 1 (8bit only)
PIO assemble 1,"out pins,8 [1]" 'write out to 7(8) pins delay 1 (8bit only)
PIO assemble 1,"out pins,8 [1]" 'write out to 7(8) pins delay 1 (8bit only)
PIO assemble 1,".wrap"
PIO assemble 1,".end program list"

'pio config
f=133e6               'default: modify this value to tune to other frequencies
p=Pio(pinctrl 0,0,bits%,,,,gp6)
e=Pio(execctrl gp0,Pio(.wrap target),Pio(.wrap))
s=Pio(shiftctrl 0,0,0,0,0,1)


'here we do UI and create sine waves
Do
 'input frequency
 Input "what frequency ";x
 y%=1+x/16000            'y%=number of sine cycles in one buffer
 f=x*2*length%/y%
 Print x,y%,f
 Timer = 0

 'stop running machine
 If MM.Info(PIO TX DMA)=1 Then
   Print "stop PIO"
   PIO STOP 1,0
   Print "stop DMA"
   PIO dma tx off
 EndIf

 'calculate sinewave table
 calc_sin  '-or- calc_modsin
 'Memory pack o%(),pkd%(),length%,32   'fill it with values from the sine wave for 32 bits
 Memory pack o%(),pkd%(),length%,8     'fill it with values from the sine wave for 8 bits

 'restart machine
 PIO init machine 1,0,f,p,e,s,0
 'PIO dma tx 1,0,&hffffffff,pkd%(),help,,length% '5.0707 command longest run 32 bits
 PIO dma tx 1,0,0,pkd%(),,,length%/4  '5.070807 command infinite run 8 bit
 'PIO dma tx 1,0,0,pkd%(),,,length%  '5.070807 command infinite run 32 bit
Loop
End



Sub help '5.0707 only
 Print "stopped after ";Timer;" ms"
 PIO stop 1,0
End Sub


Sub calc_modsin
'calculate sinewave table
For i=0 To length%-1
 alpha=i*2*Pi/length%
 o%(i)=Int(level*(1.1+(Sin(y%*alpha))*Sin(alpha)*Sin(alpha)))
Next
End Sub

Sub calc_sin
'calculate sinewave table
For i=0 To length%-1
 o%(i)=Int(level*(1.1+Sin(y%*i*2*Pi/length%)))
Next
End Sub

'create your output pin
Setpin gp0,dout

'call SUB Flip every 500ms. This is SETTICK 1. You can have up to 4 running.
SETTICK 500, flip, 1

do
loop until the_end_of_time

SUB flip
 PIN(gp0) = NOT(PIN(gp0))
end sub