Function round(value!,decs%) As float
 round = Cint(value!*10^decs%)/10^decs%
End Function

> option list
WebMite MMBasic Version 5.07.07
OPTION COLOURCODE ON
OPTION DISPLAY 40, 110
OPTION WIFI MyAccessPoint, *********
OPTION TCP SERVER PORT 80, 6000

> files
A:/
  <DIR>  .
  <DIR>  ..
00:00 01-01-2000          4  bootcount
00:15 01-01-2000       1152  favicon.ico
21:32 17-05-2023       4881  go.bas
22:01 17-05-2023        128  index.html
22:02 17-05-2023        128  test4.html
00:14 01-01-2000       2688  thermo.html
2 directories, 6 files, 593920 bytes free
>

Option explicit
Option default integer
Dim myfloat!=16.123
Dim myint%=999
Dim mystring$="The PicoMite Web is GO!!!"
Dim buff%(512)
Dim pp$="INDEX"
Const maxargs=20
Const ds18B20pin = 4
Const relaypin = 2
Const stemp=17 'setting for lowest temperature on radio buttons
Const heatingoff$=" BGCOLOR='#00ff00'>Off"
Const heatingon$=" BGCOLOR='#ff0000'>On "
Const check$="checked='checked' "
Const hysteresis=0.5
'
Dim checked$(11)
Dim integer setpointb=4 'setting for default temperature
Dim integer setpointt=stemp+setpointb-1
Dim notstarted=1,notended=0
Dim float currenttemp,readtemp
Dim float maxtemp, mintemp
Dim heating$=heatingon$
checked$(setpointb)=check$
SetPin relaypin,dout
currenttemp=TEMPR(ds18b20pin)
maxtemp=currenttemp
mintemp=currenttemp
updateheater
On error skip
WEB ntp -3 ' nova scotia daylight savings time
WEB tcp interrupt TCPrequest
PRINT "Listening @ "+mm.info(ip address) ' LB
Do
If Right$(Time$,1)="0" And notstarted=1 Then
  TEMPR START ds18b20pin,3
  notstarted=0
  notended=1
EndIf
If Right$(Time$,1)="2" And notended=1 Then
  readtemp=TEMPR(ds18b20pin)
  If readtemp<1000 Then currenttemp=readtemp
  notstarted=1
  notended=0
  maxmin
  updateheater
EndIf
'  poll
Loop
Sub TCPrequest
Local a%,s$,page$,i,nparams%
Local arg$(1,maxargs-1)
For a%=1 To MM.Info(max connections)
  If Not MM.Info(TCP request a%) Then Continue For
  LongString clear buff%()
  WEB tcp read a%,buff%()
  If LLen(buff%()) Then
'    Print "Received ",LLen(buff%())," bytes on PCB ",a%-1
'    LongString print buff%()
  page$=parsehtmldata$(nparams%,buff%(), arg$())
  Print page$
  For i=0 To nparams%
    Print arg$(0,i),"=",arg$(1,i)
    If arg$(0,i)="RB" Then ' setting for radio button
      checked$(setpointb)=""
      Print Val(Right$(arg$(1,i),Len(arg$(1,i))-1))
      setpointb=Val(Right$(arg$(1,i),Len(arg$(1,i))-1))
      setpointt=setpointb+stemp-1
      checked$(setpointb)=check$
      updateheater
    EndIf
    If arg$(0,i)="RESET" And arg$(1,i)="YES" Then 'Reset maxmin
      maxtemp=currenttemp
      mintemp=currenttemp
    EndIf
  Next
  If UCase$(page$)="INDEX"  Then
    Print "sending test page"
    pp$=page$
    WEB transmit page a%,"test4.html"
  ElseIf UCase$(page$)="THERMO" Then
    Print "sending thermostat page"
    pp$=page$
    WEB transmit page a%,"thermo.html"
  ElseIf page$="small.jpg" Then
    Print "Sending picture"
    WEB transmit file a%,"small.jpg","image/jpeg"
  ElseIf page$="favicon.ico" Then
     Print "sending favicon"
     WEB Transmit FILE a%,"favicon.ico","image/vnd.microsoft.icon"
  Else
      s$=LGetStr$(buff%(),1,Min(255,LLen(buff%())))
      Print s$
      WEB transmit code a%, 404
  EndIf
EndIf
Next a%
End Sub
'
Function parsehtmldata$(paramcount As integer, inbuf() As integer, arg$())
Const starttext$="HTTP"
Local a$,b$
Local integer buf(Bound(inbuf()))
Local integer inpos,startparam,processargs
paramcount=0
inpos=LInStr(inbuf(),"GET /",1)
If inpos=0 Then
  parsehtmldata$=""
Else
  LongString MId buf(),inbuf(),inpos+5
  inpos=LInStr(buf(),starttext$,1)
  If inpos>2 Then 'page request found
    inpos=inpos-2
    a$=LGetStr$(buf(),1,inPos)
    inpos=Instr(a$,"?")
    If inpos<>0 Then 'parameters found
      processargs=1
      parsehtmldata$=Left$(a$,inpos-1)
      a$=Mid$(a$,inpos+1)
      Do
        arg$(0,paramcount)=""
        arg$(1,paramcount)=""
        inpos=Instr(a$,"=")
        startparam=1
        arg$(0,paramcount)=Mid$(a$,startparam,inpos-startparam)
        startparam=inpos+1
        inpos=Instr(a$,"&")
        If inpos<>0 Then
          arg$(1,paramcount)=Mid$(a$,startparam,inpos-startparam)
          a$=Mid$(a$,inpos+1)
          paramcount=paramcount+1
        Else
          arg$(1,paramcount)=Mid$(a$,startparam)
          paramcount=paramcount+1
          processargs=0
        EndIf
      Loop While processargs
    Else
      parsehtmldata$=a$
    EndIf
  Else ' no page requested
    parsehtmldata$="INDEX"
  EndIf
EndIf
End Function
Sub maxmin
If currenttemp>maxtemp Then
  maxtemp=currenttemp
EndIf
If currenttemp<mintemp Then
  mintemp=currenttemp
EndIf
End Sub
Sub updateheater
'  Print "current setpoint is    ",setpointt
'  Print "current temperature is ",currenttemp
Local float hcalc
If setpointt=stemp+11 Then
  Pin(relaypin)=1
  heating$=heatingon$
ElseIf setpointt=stemp Then
  Pin(relaypin)=0
  heating$=heatingoff$
Else
  hcalc = setpointt + hysteresis
  If currenttemp>=hcalc Then 'turn heating off
    Pin(relaypin)=0
    heating$=heatingoff$
  EndIf
  hcalc = setpointt - hysteresis
  If currenttemp<=hcalc Then 'turn heating on
    Pin(relaypin)=1
    heating$=heatingon$
  EndIf
EndIf
End Sub

<html>
<head>
<title>
Remote Thermostat</title></head
<link rel="icon" type="image/x-icon" sizes="16x16" href="data:image/png;base64,
'AAABAAEAEBAQAAEABAAoAQAAFgAAACgAAAAQAAAAIAAAAAEABAAAAAAAg
'AAAAAAAAAAAAAAAEAAAAAAAAAAAAAAAAP//ADMA/wD/AAQAFf8AAAIACABZAP8AAAAAAAAAAAAAAAAAAAAAA
'AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAFAAUAVQBVAAUABQUABQBQBVAFBQAFAFAFBQAAVQBVAAUFB
'QAAAAAABVAAAAAAAAAAAAAAAAAAACREMzERAAAAJkRDMxEQAAAmZEQzMREAAAZmREMzERAAAGZkRDMxEQAAB
'mZEQzMREAAAZmREMzERAAAGZkRDMxH//wAAuzMAALrtAACa7QAArzMAAKv/AACf/wAA//8AAAA/AAAAHwAAA
'A8AAIAHAADAAwAA4AEAAPAAAAD4AAAA" />
' (REMOVE THE COMMENTS ABOVE to get the image to work--all one long line)
<body>
<form name='f1' method='get' action='{pp$}'>
<h2 align='left'>Remote Thermostat Control System V1.0</h2>
Update Code: <input type='text' name='CODE' size='6' value='000000'>

<TABLE BORDER='1' CELLSPACING='0' CELLPADDING='5'>
<TR><TD>Heating</TD><TD{heating$}</TD></TR>
</TABLE>

<TABLE BORDER='1' CELLSPACING='0' CELLPADDING='5'><TR><TD></TD>
<TD>Temperature</TD></TR><TR><TD>Current</TD><TD> {str$(currenttemp,4,1)}°C
</TD><TR><TD>Max</TD><TD> {str$(maxtemp,4,1)}°C
</TD><TR>
<TD>Min</TD><TD> {str$(mintemp,4,1)}°C
</TD>
</TABLE>

<input name='RESET' type='checkbox' value='YES' onClick='this.form.submit()'>
Reset Max/Min

<TABLE BORDER='1' CELLSPACING='0' CELLPADDING='5'><TR><TD>Thermostat</TD>
<TD><input name='RB' type='radio' value='R0' {checked$(0)} onClick='this.form.submit()'> Off
</TD>
<TD><input name='RB' type='radio' value='R1' {checked$(1)} onClick='this.form.submit()'> {stemp}
</TD>
<TD><input name='RB' type='radio' value='R2' {checked$(2)} onClick='this.form.submit()'> {stemp+1}
</TD>
<TD><input name='RB' type='radio' value='R3' {checked$(3)} onClick='this.form.submit()'> {stemp+2}
</TD>
<TD><input name='RB' type='radio' value='R4' {checked$(4)} onClick='this.form.submit()'> {stemp+3}
</TD>
<TD><input name='RB' type='radio' value='R5' {checked$(5)} onClick='this.form.submit()'> {stemp+4}
</TD>
<TD><input name='RB' type='radio' value='R6' {checked$(6)} onClick='this.form.submit()'> {stemp+5}
</TD>
<TD><input name='RB' type='radio' value='R7' {checked$(7)} onClick='this.form.submit()'> {stemp+6}
</TD>
<TD><input name='RB' type='radio' value='R8' {checked$(8)} onClick='this.form.submit()'> {stemp+7}
</TD>
<TD><input name='RB' type='radio' value='R9' {checked$(9)} onClick='this.form.submit()'> {stemp+8}
</TD>
<TD><input name='RB' type='radio' value='R10' {checked$(10)} onClick='this.form.submit()'> {stemp+9}
</TD>
<TD><input name='RB' type='radio' value='R11' {checked$(11)} onClick='this.form.submit()'> On
</TD>
</TABLE>

</form>
</body></html>

THERMO
CODE    =       4321
RB      =       R6
6
       =
sending thermostat page