' Reads a port connected to a NES gamepad.
'
' @param idx%   controller port: A = 0 or B = 1.
' @return       bitmap corresponding to current controller state:
'                 7 6 5 4 3 2 1 0
'                 ^ ^ ^ ^ ^ ^ ^ ^
'                 | | | | | | | +-- Button A
'                 | | | | | | +---- Button B
'                 | | | | | +------ Select
'                 | | | | +-------- Start
'                 | | | +---------- Up
'                 | | +------------ Down
'                 | +-------------- Left
'                 +---------------- Right
'
' Note that in theory it should not be necessary to pulse the clock pin after
' reading bit 7 (Right), but in practice there are some clone NES controllers
' which return the wrong value on subsequent reads of bit 7 if it not pulsed.
Function ctrl_read_nes%(idx%)
 Local i%
 Pulse NES_LATCH_PIN%(idx%), NES_PULSE_DURATION!
 For i% = 0 To 7
   Inc ctrl_read_nes%, Not Pin(NES_DATA_PIN%(idx%)) * 2^i%
   Pulse NES_CLOCK_PIN%(idx%), NES_PULSE_DURATION!
 Next
End Function

' Reads a port connected to a SNES gamepad.
'
' @param idx%   controller port: A = 0 or B = 1.
' @return       bitmap corresponding to current controller state:
'                 11 10 9 8 7 6 5 4 3 2 1 0
'                 ^  ^  ^ ^ ^ ^ ^ ^ ^ ^ ^ ^
'                 |  |  | | | | | | | | | +-- Button B
'                 |  |  | | | | | | | | +---- Button Y
'                 |  |  | | | | | | | +------ Select
'                 |  |  | | | | | | +-------- Start
'                 |  |  | | | | | +---------- Up
'                 |  |  | | | | +------------ Down
'                 |  |  | | | +-------------- Left
'                 |  |  | | +---------------- Right
'                 |  |  | +------------------ Button A
'                 |  |  +-------------------- Button X
'                 |  +----------------------- Left Bumper
'                 +-------------------------- Right Bumper
Function ctrl_read_snes%(idx%)
 Local i%
 Pulse NES_LATCH_PIN%(idx%), NES_PULSE_DURATION!
 For i% = 0 To 11
   Inc ctrl_read_snes%, Not Pin(NES_DATA_PIN%(idx%)) * 2^i%
   Pulse NES_CLOCK_PIN%(idx%), NES_PULSE_DURATION!
 Next
End Function

' Reads a port connected to an ATARI 1-button joystick.
'
' @param idx%   controller port: only port A = 0 is supported.
' @return       bitmap corresponding to current controller state:
'                 7 6 5 4 3 2 1 0
'                 ^ ^ ^ ^ ^ ^ ^ ^
'                 | | | | | | | +-- Fire Button
'                 | | | | | | +---- unused
'                 | | | | | +------ unused
'                 | | | | +-------- unused
'                 | | | +---------- Up
'                 | | +------------ Down
'                 | +-------------- Left
'                 +---------------- Right
Function ctrl_read_atari%(idx%)
 Inc ctrl_read_atari%, Not Pin(ATARI_FIRE_PIN%(idx%))
 Inc ctrl_read_atari%, Not Pin(ATARI_UP_PIN%(idx%)) * 16
 Inc ctrl_read_atari%, Not Pin(ATARI_DOWN_PIN%(idx%)) * 32
 Inc ctrl_read_atari%, Not Pin(ATARI_LEFT_PIN%(idx%)) * 64
 Inc ctrl_read_atari%, Not Pin(ATARI_RIGHT_PIN%(idx%)) * 128
End Function