'circle, a 2 player game for VGA picomite GAME

'features PIONES2 - PIO SPI for dual NES controller
'VGApicomiteGAME board revision 1.4

'---------------------------- IO pin configuration -------------------------
'pin asignment K8/sm0 K7/sm1
'data (in)     gp1    gp4
'latch (out)   gp2    gp5
'clk (out)     gp3    gp22

'reserve pins for PIO1 sm0
SetPin gp1,pio1:SetPin gp2,pio1:SetPin gp3,pio1  'sm0
SetPin gp4,pio1:SetPin gp5,pio1:SetPin gp22,pio1 'sm1

'power the 2 ports K8 and K7 if needed
SetPin gp14,dout:Pin(gp14)=1
SetPin gp15,dout:Pin(gp15)=1


'------------------------------ PIO configuration --------------------------
'PIO1 execute frequency
f=100000

'pio config PIO1 sm0
s0=2^19                            'default with IN shift left, OUT shift right
p0=Pio(pinctrl 1,1,1,GP1,GP3,GP2,GP3)  'GP1=IN base GP2=SET GP3=OUT/SIDESET

'pio config PIO1 sm1
s1=2^19                           'default with IN shift left, OUT shift right
p1=Pio(pinctrl 1,1,1,GP4,GP22,GP5,GP22) 'GP4=IN base, GP5=SET GP22=OUT/SIDESET


'------------------------------ PIO program (comment) -----------------------
'pio1 sm0 program, identical code for sm0 and sm1, clock is side set pin
'adr/instr/comment
'0 E081 'set pindir latch, out     [side 0]
'1 E000 'set latch low             [side 0]
'2 A0EB 'MOV null inverted to OSR  [side 0]
'3 6081 'OUT 1 bit OSR to pindirs  [side 0] set clock output

'4 E001 'latch high                [side 0] latch pulse
'5 E000 'latch low                 [side 0]
'6 E027 'load X with value 7       [side 0]
'7 A0C3 'mov NULL to ISR           [side 0]

'8 4001 'shift 1 bit data in ISR   [side 0]
'9 1048 'JMP X-- to &h8            [side 1] this is the clock pulse
'A 8000 'push ISR                  [side 0] 8 bits to fifo
'B 0004 'jmp to &h4                [side 0] next cycle

'&h0C....&h1F not used
'------------------------- END PIO program (comment) --------------------------

'pio1 program in data statements
Dim a%(7)=(&h6081A0EBE000E081,&hA0C3E027E000E001,&h0004800010484001,0,0,0,0,0)

'program and start the PIO1 state machines
PIO program 1,a%()      'program PIO1
PIO init machine 1,0,f,p0,,s0,0       'init sm0 from address &h00
PIO init machine 1,1,f,p1,,s1,0       'init sm1 from address &h00 (same code)
PIO start 1,0                         'start PIO1 sm0
PIO start 1,1                         'start PIO1 sm1

Dim h%(5)

'------------------------------ MAIN level -----------------------------------

MODE 2

'initial values for the players and the target food
'target (green) index 0, left player (K8/port A/blue) index 1
'right player (K7/port B/ red) index 2
sz=MM.HRes/40

'x,y are coordinates, r=radius, c=color, s=speed
x0=MM.HRes/2:y0=MM.VRes/3:r0=sz:c0=RGB(green)
x1=MM.HRes/3:y1=2*MM.VRes/3:r1=sz:c1=RGB(blue):s1=5
x2=2*MM.HRes/3:y2=2*MM.VRes/3:r2=sz:c2=RGB(red):s2=5

FRAMEBUFFER create
FRAMEBUFFER write f

'initial target
Circle x0,y0,r0,,,c0,c0

'this is the main game loop. the gams stops when one player
'size exceeds the screen limits
Do
'read the FIFO's that contain the NES controller keys
PIO read 1,0,5,h%()  'read 5 words from FIFO sm0
p1=255-h%(4)         'converto to value 0-15
PIO read 1,1,5,h%()  'read 5 words from FIFO sm1
p2=255-h%(4)         'converto to value 0-15

'wipe old positions players
 Circle x1,y1,r1,,,0,0
 Circle x2,y2,r2,,,0,0

 'move players
   v1=0:v2=0
   if (p1 and 2) then v1=v1+s1:x1=x1-s1
   if (p1 and 1) then v1=v1+s1:x1=x1+s1
   if (p2 and 2) then v2=v2+s2:x2=x2-s2
   if (p2 and 1) then v2=v2+s2:x2=x2+s2
   if (p1 and 8) then v1=v1+s1:y1=y1-s1
   if (p1 and 4) then v1=v1+s1:y1=y1+s1
   if (p2 and 8) then v2=v2+s2:y2=y2-s2
   if (p2 and 4) then v2=v2+s2:y2=y2+s2
   
   'allow wrap around
   if x1<0 then x1=x1+mm.hres
   if x1>mm.hres then x1=x1-mm.hres
   if y1<0 then y1=y1+mm.vres
   if y1>mm.vres then y1=y1-mm.vres
   if x2<0 then x2=x2+mm.hres
   if x2>mm.hres then x2=x2-mm.hres
   if y2<0 then y2=y2+mm.vres
   if y2>mm.vres then y2=y2-mm.vres
 
  'calculate distances
  d12=Sqr((x1-x2)^2 + (y1-y2)^2)
  d10=Sqr((x1-x0)^2 + (y1-y0)^2)
  d20=Sqr((x0-x2)^2 + (y0-y2)^2)

  'game rules, collision between players is punished
  'player who moves is culprit
  If d12<(r1+r2) Then
     If v1>0 Then r1=r1/2
     If v2>0 Then r2=r2/2
     r1=max(r1,1)
     r2=max(r2,1)
  EndIf
 
  'you eat, you grow....
  If d10<(r1+r0) Then
    r1=r1*2
    newfood
  EndIf
  If d20<(r0+r2) Then
    r2=r2*2
    newfood
  EndIf
 
 'write new player /target positions and sizes
 Circle x1,y1,r1,,,c1,c1
 Circle x2,y2,r2,,,c2,c2
 Circle x0,y0,r0,,,c0,c0

 FRAMEBUFFER copy f,n,b
 Pause 50
 
Loop while r1<MM.Vres and r2<MM.vres
End

Sub newfood
 Circle x0,y0,r0,,,0,0
 x0=MM.HRes*Rnd()
 y0=MM.VRes*Rnd()
end sub
 
end sub

'PIONES16 - PIO SPI for SNES controller
'VGApicomiteGAME board revision 1.4
'Shrink version (both stamemachines run same code)

'-------------------------------- IO pin configuration -------------------------
'pin asignment K8/sm0 K7/sm1
'data (in)     gp1    gp4
'latch (out)   gp2    gp5
'clk (out)     gp3    gp22

'reserve pins for PIO1 sm0
SetPin gp1,pio1:SetPin gp2,pio1:SetPin gp3,pio1  'sm0
SetPin gp4,pio1:SetPin gp5,pio1:SetPin gp22,pio1 'sm1

'power the 2 ports K8 and K7 if needed
SetPin gp14,dout:Pin(gp14)=1
SetPin gp15,dout:Pin(gp15)=1


'--------------------------------- PIO configuration --------------------------
'PIO1 execute frequency
f=200000   '200kHz to achieve same responsiveness as 100kHz 8 bit controller

'note: the PIO program for both PIO's is the same, only the IO definition
'in the pinctrl register is different. The statemachines actually run same code

'pio config PIO1 sm0
s0=2^19                            'default with IN shift left, OUT shift right
p0=Pio(pinctrl 1,1,1,GP1,GP3,GP2,GP3)  'GP1=IN base GP2=SET GP3=OUT/SIDESET

'pio config PIO1 sm1
s1=2^19                           'default with IN shift left, OUT shift right
p1=Pio(pinctrl 1,1,1,GP4,GP22,GP5,GP22) 'GP4=IN base, GP5=SET GP22=OUT/SIDESET


'------------------------------ PIO program (comment) -------------------------
---
'pio1 sm0 program, identical code for sm0 and sm1, clock is side set pin
'adr/instr/comment
'0 E081 'set pindir latch, out     [side 0]
'1 E000 'set latch low             [side 0]
'2 A0EB 'MOV null inverted to OSR  [side 0]
'3 6081 'OUT 1 bit OSR to pindirs  [side 0] set clock output

'4 E001 'latch high                [side 0] latch pulse
'5 E000 'latch low                 [side 0]
'6 E02F 'load X with value 15      [side 0]  <---------change no of bits to 15
'7 A0C3 'mov NULL to ISR           [side 0]

'8 4001 'shift 1 bit data in ISR   [side 0]
'9 1048 'JMP X-- to &h8            [side 1] this is the clock pulse
'A 8000 'push ISR                  [side 0] 16 bits to fifo
'B 0004 'jmp to &h4                [side 0] next cycle

'&h0C....&h1F not used
'------------------------- END PIO program (comment) --------------------------
-

'pio1 program in data statements
Dim a%(7)=(&h6081A0EBE000E081,&hA0C3E02FE000E001,&h0004800010484001,0,0,0,0,0)

'program and start the PIO1 state machines
PIO program 1,a%()      'program PIO1
PIO init machine 1,0,f,p0,,s0,0       'init sm0 from address &h00
PIO init machine 1,1,f,p1,,s1,0       'init sm1 from address &h00 (same code)
PIO start 1,0                         'start PIO1 sm0
PIO start 1,1                         'start PIO1 sm1


'------------------------------ MAIN level -----------------------------------
Print "running"
dim h%(4)

'read the FIFO's that contain the NES controller keys
Do
 PIO read 1,0,5,h%() 'read from FIFO sm0
 Print Hex$(65535-h%(4)), 'print value
 PIO read 1,1,5,h%() 'read from FIFO sm1
 Print Hex$(65535-h%(4)) 'print value
 Pause 100
Loop While Inkey$=""

End

# <type> can be one of "none", "nes", "snes" or "atari"
# without the quotes.
port-a=<type>
port-b=<type>

'SSTV decoder program for ROBOT-8 mode for PICOMITE MMBasic
Option default integer
MODE 1

'pio program measure overlapping rising and falling period and send to FIFO
'loops increment both X and Y, alternating X and Y are reset and pushed.
'0 E020   'set X=0
'1 A029   'X -> fffffff
'2 00C5   'jmp (pin=1) to loop2
'3 0084   'Y-- (first loop Y contains rubbish)
'4 0042   'count X-- loop1
'5 A0CA   'mov -Y to ISR
'6 8000   'push noblock    //nopush A042 = MOV Y,Y
'7 E040   'set Y=0
'8 A04A   'Y -> fffffff
'9 004A   'count X-- loop2
'A 008B   'Y--
'B 00C9   'jmp (pin=1) in loop2
'C A0C9   'mov -X to ISR
'D 8000   'push noblock   //nopush A042 = MOV Y,Y
'E 0000   'jmp 0 (rest is filled with 0 = jmp->0)
'SSTV reference
Dim a%(7)=(&h008400C5A029E020,&hE0408000A0CA0042,&h00C9008B004AA04A,&h8000A0C9,0,0,0,0)
'SSTV nopush
'Dim a%(7)=(&h008400C5A029E020,&hE040A042A0CA0042,&h00C9008B004AA04A,&hA042A0C9,0,0,0,0)
f=3e6     '3MHz @ 3cycles per loop = 1us per tick

'configure pio1
e=Pio(execctrl 0,0,&h1f)  'use gp0 for PIN
s=Peek(word &h503000d0)   'use old value
p=0                       'no GPxx pins for PIO1

'program pio1 and start
PIO program 1,a%()
PIO init machine 1,0,f,p,e,s
PIO start 1,0

'pio fifo register
ff=&h50300020

'sstv specific frequecies converted to time in us
l=1e6/1100 'sync low
r=1e6/1200 'sync
u=1e6/1300 'sync high
b=1e6/1500 'black
v=1e6/1900 'black/white threshold
w=1e6/2300 'white

menu:
CLS
Print "SSTV Robot-8 playground":Print
Print "1 = measure frequency"
Print "2 = waterfall"
Print "3 = picture in burst mode (no hsync)"
Print "4 = picture monochrome"
Print "5 = picture in 4 green levels"
Print "6 = picture in dithered white"
Print "7 = stop"
Do
 kn$=Inkey$
Loop Until kn$<>""
Select Case Val(kn$)
 Case 1
   GoSub frequency
 Case 2
   GoSub waterfall
 Case 5
   GoSub greenvideo
 Case 3
   GoSub videobrute
 Case 6
   GoSub greyvideo
 Case 4
   GoSub video
 Case 7
   End
End Select
GoTo menu




frequency:
'measure time and convert to frequency
Do
 cnt=Peek(word ff) 'read fifo pio 1 seq 0
 period = cnt+3      'period
 Print @(300,240) Int(1e6/period);" Hz      "
 Pause 100
Loop While Inkey$=""
Return




waterfall:
'show frequency graph on horizontal axis, scolling down
CLS
Do
 Text 1,1,"frequency (Hz)","LT"
 Text r/2,1,"1200","CT"
 Text b/2,1,"1500","CT"
 Text w/2,1,"2300","CT"
 Line u/2,20,u/2,479
 Line l/2,20,l/2,479
 For y=20 To 479
   'poke word &h503000d8,&h8000 'push
   'pause 0.020
   cnt=Peek(word ff)
   Pixel cnt/2,y,1
   Pause 0.5   'delay to slow waterfall
 Next y
 CLS
Loop While Inkey$=""
Return




video:
'video decode using both hsync and vsync
're-syncing every line and frame
Do
 'CLS
 y=180
 Do
   x=240
   Timer =0
   'pixel video read an display
   Do
     Pause 0.3 'horizontal timing
     x=Min(390,x+1)
     p=Peek(word ff)
     Pixel x,y,(p<v)
   Loop Until p>u And Timer>58
   Timer =0
   'hsync detect > 3.5ms, vsync > 10ms
   Do
     Pause 0.3 'lower misses syncs
     p=Peek(word ff)
   Loop Until p<u And Timer>3.5
   If Timer > 10 Then Exit
   Inc y
 Loop
Loop While Inkey$=""
Return




videobrute:
'video decode fixed timing from vertical sync

brute:
'find vsync
Do
 Do
   p=Peek(word ff)
 Loop Until p>u
 Timer =0
 Do
   p=Peek(word ff)
 Loop Until p<b
Loop Until Timer > 10

'brute force process all pixels and hsync equally
For y=180 To 298
 For x=240 To 359
   p=Peek(word ff)
   Pixel x,y,(p<v)
   Pause 0.487
 Next x
Next y
If Inkey$="" Then GoTo brute
Return




greenvideo:
'video decode in mode 2 using 4 level green
're-syncing every line and frame
MODE 2
Dim c%(3)=(0,&h4000,&h8000,&hC000) '3 green levels and black

Do
 CLS
 y=50
 Do
   x=80
   'capture pixel data and display
   Timer =0
   Do
     Pause 0.3 'rough horizontal timing
     x=Min(220,x+1)
     p=Peek(word ff)
     i=(p<580)+(p<522)+(p<470)
     Pixel x,y,c%(i)
   Loop Until p>u And Timer>60
   Timer =0
   'detect end of hsync to start new line
   Do
     p=Peek(word ff)
   Loop Until p<b And Timer>4
   If Timer > 10 Then Exit 'sync is vsync
   Inc y
 Loop
Loop While Inkey$=""
MODE 1
Return


greyvideo:
'create greyscale out of 3x3 tiles in B/W pixels
're-syncing every line and frame

CLS
'create 10 3x3 sprites
make_dither
Do
 y=50
 Do
   x=100
   'dither pixels by blit of 3x3 sprite
   Timer =0
   Do
     Pause 0.24
     x=Min(500,x+3)
     p=Peek(word ff)
     n=min(max((640-p)/22,0),9) 'convert to sprite index
     blit 0,40+(3*n),x,y,3,3
   Loop Until p>u And Timer>60
   Timer =0
   Print @(0,0) x
   'detect end of hsync to start new line
   Do
     p=Peek(word ff)
   Loop Until p<u And Timer>3.5
   If Timer > 10 Then Exit 'sync is a vsync
   Inc y,3
 Loop Until y>407
Loop While Inkey$=""
Return



sub make_dither
'create 10 3x3 dither sprites that are blit onto the screen in stead of drawing pixels
x=0:y=40
'black = do nothing
y=y+3
'1 pixel
pixel x+1,y+1
y=y+3
'2pixels
pixel x,y:pixel x+2,y+2
y=y+3
'3pixels
pixel x,y:pixel x+1,y+2:pixel x+2,y+1
y=y+3
'4pixels
pixel x,y+1:pixel x+1,y:pixel x+1,y+2:pixel x+2,y+1
y=y+3
'5pixels
pixel x,y:pixel x,y+2:pixel x+1,y+1:pixel x+2,y:pixel x+2,y+2
y=y+3
'6 pixels
pixel x,y:pixel x,y+1:pixel x+1,y+1
pixel x+1,y+2:pixel x+2,y:pixel x+2,y+2
y=y+3
'7pixels
pixel x,y:pixel x,y+1:pixel x,y+2:pixel x+1,y+1
pixel x+1,y+2:pixel x+2,y:pixel x+2,y+2
y=y+3
'8pixels
pixel x,y:pixel x,y+1:pixel x,y+2:pixel x+1,y+1
pixel x+1,y+2:pixel x+2,y:pixel x+2,y+1:pixel x+2,y+2
y=y+3
'9pixels
box x,y,3,3,1,1,1
end sub