'test HW for sine wave generator

'this is running in basic
bits% = 7
length% = 64' 128

'calculate sinewave table
level=2^(bits%-1)*0.9
Dim o%(length%-1)
For i=0 To length%-1
 o%(i)=Int(level*(1.1+Sin(i*2*Pi/length%)))
Next

'pack data in ring buffer
'shortest ring buffer is 256
Dim pkd%
PIO make ring buffer pkd%,length%*4  'length in 32 bit fifo values
Memory pack o%(),pkd%(),length%,32   'fill it with values from the sine wave

'pio pins
SetPin gp6,pio1
SetPin gp7,pio1
SetPin gp8,pio1
SetPin gp9,pio1
SetPin gp10,pio1
SetPin gp11,pio1
SetPin gp12,pio1

'pio program
PIO assemble 1,".program out"
PIO assemble 1,".line 0"
PIO assemble 1,"mov osr ,!null" 'fill osr with &hffffffff
PIO assemble 1,"out pindirs,32" 'set all associated pins output
PIO assemble 1,".wrap target"
PIO assemble 1,"pull noblock"   'get data from fifo
PIO assemble 1,"out pins,32"    'write out to 7 pins
PIO assemble 1,".wrap"
PIO assemble 1,".end program list"

'pio config
f=133e6               'modify this value to tune to other frequencies

p=Pio(pinctrl 0,0,bits%,,,,gp6)
e=Pio(execctrl gp0,Pio(.wrap target),Pio(.wrap))
s=Pio(shiftctrl 0,0,0,0,0,1)
's=Pio(shiftctrl 0,bits%,0,1,0,1)     'autopull after 'bits' shift out

PIO init machine 1,0,f,p,e,s,0
Print "machine init"

'now start the actual machine
PIO dma tx 1,0,&hffffffff,pkd%(),help,,length%
Print "dma running"

'here we do nothing , or some UI
Do :Loop

Sub help
Print "help"
PIO stop 1,0
End Sub

End

gp6  gp7  gp8 gp9 gp10  gp11
!    !    !    !    !    !
2k   2k   2k  2k   2k   2k
!    !    !    !    !    !
+-1k-+-1k-+-1k-+-1k-+-1k-+--- output
!
2k
!
GND

    !'
-----!+ '
    !   :---+--- output
    !  .    !
  --!-.     !
  ! !.      !
  !_________!

Simple buffer

'Sine wave generator 1Hz...1MHz using a ladder DAC on Picomite 5.07.07
'amplitude resolution defined in variable "bits%". In demo this is 7 bits on GP6...GP12
'uses PIO to output pre-calculated data through ring buffer DMA.

bits% = 7
length% = 4096          'allows up to 16kHz full resolution '64' 128
Dim o%(length%-1)
level=2^(bits%-1)*0.9   'amplitude of sine signal

'this uses the ring buffer.
Dim pkd%
PIO make ring buffer pkd%,length%*4  'length in 32 bit fifo values in bytes

'setup the pio pins for the ladder DAC
SetPin gp6,pio1
SetPin gp7,pio1
SetPin gp8,pio1
SetPin gp9,pio1
SetPin gp10,pio1
SetPin gp11,pio1
SetPin gp12,pio1

'pio program to send DMA data to the pins
PIO assemble 1,".program out"
PIO assemble 1,".line 0"
PIO assemble 1,"mov osr ,!null" 'fill osr with &hffffffff
PIO assemble 1,"out pindirs,32" 'set all associated pins output
PIO assemble 1,".wrap target"
PIO assemble 1,"pull noblock"   'get data from fifo
PIO assemble 1,"out pins,32"    'write out to 7 pins
PIO assemble 1,".wrap"
'PIO assemble 1,".end program list"
PIO assemble 1,".end program"

'pio config (this is the default value)
f=133e6               'modify this value to tune to other frequencies
p=Pio(pinctrl 0,0,bits%,,,,gp6)
e=Pio(execctrl gp0,Pio(.wrap target),Pio(.wrap))
s=Pio(shiftctrl 0,0,0,0,0,1)

'here we set the frequency and program the sine wave, PIO and DMA
Do
 'for frequencies < 16kHz we use the full buffer for 1 single cycle
 'for higher frequencies we pack multiple cycles in one buffer
 
 'input frequency  
 Input "what frequency ? ";x
 If x>16000 Then
   y%=1+x/16000            'y%=number of sine cycles in one buffer
   f=x*2*length%/y%
 Else
   f=x*2*length%           '1 sine cycle in buffer
   y%=1
 EndIf

 'stop running PIO and DMA machine
 PIO stop 1,0
 If MM.Info(PIO TX DMA)=1 Then PIO dma tx off

 'calculate new sinewave buffer and pack it into the ring buffer
 calc_sin
 Memory pack o%(),pkd%(),length%,32   'fill it with values from the sine wave

 'restart machine
 PIO init machine 1,0,f,p,e,s,0
 PIO dma tx 1,0,&hffffffff,pkd%(),help,,length%
Loop
End


Sub help
' Print "help"
PIO stop 1,0
End Sub


Sub calc_sin
 'calculate sinewave buffer values
 level=2^(bits%-1)*0.9
 For i=0 To length%-1
   o%(i)=Int(level*(1.1+Sin(y%*i*2*Pi/length%)))
 Next
End Sub