'Solar charge/discharge monitor & controler
Option EXPLICIT
Option DEFAULT NONE
Option vcc 3.302

Timer =0

Const True=1
Const False=0
'set test flags
Const test=False'for running with no hardware
Const test2=True'for running with printing debug

Const overload=20.0
Const noload=3.6
Const overvolt=14.05
Const battfull=13.5
Const battlow=12.45
Const wait4=4
Const wait6=6
Const wait12=12
Const go=2.00
Const wattsec=2.77777777E-4
Const sec=1000

Dim string txt

'battery cutoff voltage for 40% & 50% battery capacity at different currents
'Dim Float V40(4)=(12.38,12.2,11.8,11.3,11.0) '@1A,5A,10A,20A,33.3A
'Dim Float V50(4)=(12.4,12.25,12.0,11.5,11.2) '@1A,5A,10A,20A,33.3A
Dim Float Iin(4),Volt(4),Iout(4),raw(4,2),hi(2),lo(2)
Dim Float ipi,opi,outi,v,whr,wh(1),daywh(1),wkwh(1),mtwh(1)
Dim Float tot(2),last(2),filter(3,2)
'opamp offset, Input I, Output I, Batt Voltage
Dim Float offset(2)=(-0.0400,-0.0370,-0.008)
'Dim Float offset(2)=(-0.0395,-0.0365,-0.008)
'scaling factor Input I, Output I, Batt Voltage
Dim Float scale(2)=(2.27,28.25,6.795)
'Dim Float scale(2)=(2.28,28.50,6.802)
'Dim Float cor2(2)=(1.0,0.995,1.00)
Dim Integer x,y,tick,filt,idle,charging=0,P1,P2,relay,displ=1,displc
Dim Integer overld,alarm,invon=0,mainsoff,mainsrun,status=3,div(2)
Dim Integer t1=0,t2=-4,rund=0,runon,loopt=sec,hr,lhr=25,show=3,day

If test Then
' wh(0)=4024:wh(1)=3570
' daywh(0)=330:daywh(1)=-220
' wkwh(0)=1200:wkwh(1)=-1002
' mtwh(0)=4500:mtwh(1)=-3500
' day=0
Const rundly=15000'600000'15000
Const overun=30'3600'30
Const hr6=4'21000
Else
SetPin GP25, DOUT
SetPin GP14, DOUT
SetPin GP15, DOUT
SetPin GP16, DOUT
SetPin GP17, DOUT
SetPin GP5, DOUT
SetPin GP26,AIN
SetPin GP27,AIN
SetPin GP28,AIN
SetPin GP0,DIN,Pulldown

Const rundly=600000
Const overun=3600'5400
Const hr6=21000
EndIf

VAR Restore
'end program with all outputs off if program failed.
If MM.Watchdog Then
status=4
Else
ADC open 166666, 3
EndIf

'keep going as long as no major faults
Do While status<>4
WatchDog 2000
'Take 5 readings, find the max and min and remove them
'sum  the remaining values and divide by number of readings used.
'Do this 4 times and then do the same again on those 4 values
For filt=0 To 3
ADC Start Iin(0),Volt(0),Iout(0)
Math Insert raw(),,0,Iin():Math Insert raw(),,1,Iout():Math Insert raw(),,2,Volt()
'loop for each input, I in, I out, Volts.
For y=0 To 2
 tot(y)=0:div(y)=0
'use the first readings as hi & low initially
 hi(y)=raw(0,y):lo(y)=raw(0,y)
'now check the rest
 For x=1 To 4
'  Print raw(x,y),
  If hi(y)<raw(x,y) Then hi(y)=raw(x,y)
  If lo(y)>raw(x,y) Then lo(y)=raw(x,y)
 Next
'Print hi(y),lo(y),
 For x=0 To 4
  If raw(x,y)< hi(y) And raw(x,y)>lo(y) Then Inc tot(y),raw(x,y):Inc div(y)
 Next

 If div(y) Then
  filter(filt,y)=tot(y)/div(y)
 Else
  filter(filt,y)=hi(y)
 EndIf
'Print filter(filt,y)
Next
Next

' Filter out high and low readings again.
For y=0 To 2
div(y)=0:tot(y)=0
'use the first readings as hi & low initially
hi(y)=filter(0,y):lo(y)=filter(0,y)
'now check the rest
For x=1 To 3
 If hi(y)<filter(x,y) Then hi(y)=filter(x,y)
 If lo(y)>filter(x,y) Then lo(y)=filter(x,y)
Next
For x=0 To 3
 If filter(x,y)<hi(y) And filter(x,y)>lo(y) Then Inc tot(y),filter(x,y):Inc div(y)
Next
Next
For y=0 To 2
If div(y) Then
 tot(y)=tot(y)/div(y)
Else
 tot(y)=hi(y)
EndIf
'Add in ADC correction at low voltages.
' If tot(y)< 0.15 Then tot(y)=tot(y)*cor2(y)
'Print tot(y);

'Initialise 'last' values
' If last(2)<0.00001 Then last(y)=tot(y)
'rolling average over last 2 readings
' tot(y)=tot(y)*0.5+last(y)*0.5

' If tot(y)<0.0 Then tot(y)=0.0
Next

Inc tick

' Debug
If test Then
'input current
tot(0)=0.039
' If tick>5 Then tot(0)=0.91
' If tick>90 Then tot(0)=0.0
'output current
tot(1)=0.036
' If tick>42 Then tot(1)=0.22
' If tick>52 Then tot(1)=0.22
' If (tick>40 And tick<45) Or (tick>70 And tick<75) Or (tick>100 And tick<105) Then tot(1)=1.0
tot(2)=1.9
' If tick>5 Then tot(2)=2.2
' If tick>30 Then tot(2)=1.9
' If tick>40 Then tot(2)=1.6
' If tick>50 Then tot(2)=1.6
' If tick>60 Then tot(2)=1.6
' Print tot(0),tot(1),tot(2),Time$
'Print Time$
EndIf
Print tot(0),tot(1),tot(2),Time$

'remove opamp offset, then scale up.
ipi=(tot(0)+offset(0))*scale(0) 'Shunt=0-100A=0-75mV*47(gain)=0-3.5V
opi=(tot(1)+offset(1))*scale(1) 'Shunt=0-8A=0-41mV*81(gain)=0-3.32V

'calc outi for battery voltage compensation against drain current.
outi=opi-ipi
'current out very low or negative
If outi<0.01 Then
 outi=0.1
'current out over 20A, adjust compensation(for 2x50A Batteries).
ElseIf outi>20 Then
 outi=20.0+(outi-20.0)*0.45
EndIf
v=(tot(2)+offset(2))*scale(2)
'calculate Watt second for input current
whr=ipi*v*wattsec
'add up Watt seconds to give Wh
Inc daywh(0),whr
Inc wh(0),whr
'calculate Watt second for output current
whr=-opi*v*wattsec
'add up Watt seconds to give Wh
Inc daywh(1),whr
Inc wh(1),whr

If Not test Then
If Pin(GP5) Then
If charging Then
 Bitbang lcd 1,1,"C"+Format$(ipi,"%+04.1f")+"A   "+Format$(-opi,"%+05.1f")+"A"
Else
 Bitbang lcd 1,2,Format$(ipi,"%+04.1f")+"A   "+Format$(-opi,"%+05.1f")+"A"
EndIf
If tick>show+3 Then show=tick+3
'show for 3 seconds
If tick<show Then
 Bitbang lcd 2,1,Format$(v,"%5.2f")+"V   "+Format$((v*(-opi)),"%+04.0f")+"W  "
'show for 2 seconds
ElseIf tick<show+2 Then
 If wh(0)>9999 Or wh(1)>9999 Then
  Bitbang lcd 2,1,Format$(wh(0),"%+06.0f")+"Wh"+Format$(wh(1),"%+06.0f")+"Wh"
 ElseIf wh(0)>999 Or wh(1)>999 Then
  Bitbang lcd 2,1,Format$(wh(0),"%+05.0f")+"Wh "+Format$(wh(1),"%+05.0f")+"Wh "
'show for 2 seconds
 Else
  Bitbang lcd 2,1,Format$(wh(0),"%+04.0f")+"Wh  "+Format$(wh(1),"%+04.0f")+"Wh  "
 EndIf
Else
 Bitbang lcd 2,1,Format$(daywh(0),"%+04.0f")+"Wh  "+Format$(daywh(1),"%+04.0f")+"Wh  "
EndIf
EndIf
EndIf

'status=1 Running-Inverter ON, 1 o/p relay ON, mains relay ON (mains OFF).
'status=2 Standby-Inverter OFF, o/p relays OFF, mains relay ON (mains OFF).
'status=3 Battery low, or recharge mode, all relays OFF (mains ON).
'status=4 Fault-Inverter OFF, o/p relays OFF, mains relay OFF (mains ON).
'status=5 Sun gone, inverter OFF, run fridges every 3hrs, untill 24:00 then all ON over night.

'Control of the inverter & 2 relay outputs
'runtimer toggle
If t1<Timer Then t1=Timer+rundly : rund=Not rund

'loop counter timer
Inc t2

'has the battery been put in charge mode?
If charging Then
'check if voltage has risen enough to stop charging only mode?
If v>battfull Then
 charging=False:status=2:invon=False:P1=0:P2=0:relay=0
 t2=0:t1=Timer+rundly:rund=True
EndIf
EndIf

'check for electricity cheap rate time 00:00 to 08:00 BST
'get the current hour
hr=Val(Left$(Time$, 2))

'has the hour changed
If hr<>lhr Then
'standard hourly update
VAR Save wh(),daywh(),status
EndIf

'if still cheap rate electricity stay on mains power and charging
If hr>=8 Then
'is the solar input current good or battery full and not in recharge mode.
If (ipi>go Or v>battfull) And Not charging Then
'Set an overun timer, so system runs if the sun has been out in this hour
'Is this the first time for a while
 If tick>runon Then
'Give our selves an overun
  runon=tick+overun
'Reset other timer.
  t2=0:t1=Timer+rundly:rund=True
  status=2
'Keep setting the overun timer, all the time the sun is out.
 Else
  If hr<16 Then
'before 4pm set the runon
   runon=tick+overun
  Else
'later then 4pm then halve the runon
   runon=tick+overun*0.5
  EndIf
 EndIf
EndIf
'sun gone and timed out
If tick>=runon Then
'after 4pm but not enough sun
 If hr>=16 Then
  status=5
'is it 6pm or 9pm?
  If hr=18 Or hr=21 Then
   If Not mainsrun Then invon=False:t2=0:t1=Timer+rundly:rund=True
'run fridges for an hour
   mainsrun=True
  Else
'turn off fridges for remainder
   mainsrun=False
  EndIf
'not enough sun, before 4pm, run fridges normally from mains.
 Else
  If status<>3 Then status=3:P1=1:P2=1:invon=False:t2=0:t1=Timer+rundly:rund=True
 EndIf
EndIf
'before 8am, run fridges from mains
Else
If status<>3 Then status=3:P1=1:P2=1:invon=False:t2=0:t1=Timer+7000:rund=True
EndIf

'are we in a normal running mode?
If status=1 Or status=2 Then
'turn off mains power
mainsoff=True
'check if Sun has gone, power down, just charge battery.
If tick>=runon Then
 status=3
 t2=0:t1=Timer+rundly:rund=True
 invon=False:P1=1:P2=1
EndIf
' are we in an inverter on mode?
If status=1 Then
 Inc invon
'Batt v good (2x50A Batts) adjusted for load Or no significant load(fridge OFF) Or wait to avoid volt dip?
 If v>battlow-outi*0.05 Or opi<noload Or t2<wait6 Then
'Current drain good, or wait a bit to avoid surge?
  If opi<overload Or t2<wait4 Then
'Reset overload if no overload and an extended delay to be sure things have settled
   If opi<overload And t2>wait12 Then
    overld=False
   EndIf
'has the inverter powered up?
   If invon>4 Then
'is the load off or no relays active, Or after run delay.
    If ((opi<noload Or relay=0) And t2>wait4) Or (Not rund) Then
'swap over the loads, reset the timers.
     Select Case relay
      Case 0
       P1=1:P2=0:relay=1:t2=0
      Case 1
       P1=0:P2=1:relay=2:t2=0
      Case 2
       P1=0:P2=0:relay=0:status=2:t2=0
     End Select
     t1=Timer+rundly:rund=True
    EndIf
'inverter off
   EndIf
'overload
  Else
'turn off everything, increment overload counter.
   P1=0:P2=0:invon=False
   Inc overld
'set alarm, turn OFF inverter.
   If overld>2 Then
    invon=False
    status=4
    alarm=True
    t2=0:t1=Timer+rundly:rund=True
   Else
    status=2
'decrement relay, so that same output is tested again after it overloaded.
    If relay>0 Then Inc relay,-1
   EndIf
'save overload stuff to log
   Open "solar.log" For Append As #1
   Print #1, Date$" "Time$"  "Format$(daywh(0),"%4.0f")"  "Format$(wh(0),"%6.0f")"Wh In  "Format$(daywh(1),"%4.0f")"  "Format$(wh(1),"%6.0f")"Wh Out  stat="status
   Close #1
'save status to non-volatile memory
   VAR Save wh(),daywh(),status
'wait before trying again
   t1=Timer+rundly:rund=True
  EndIf
'low battery, status mode is 3 all off, activate charge.
 Else
  charging=True:status=3
  runon=tick
  t2=0:t1=Timer+rundly:rund=True
  invon=False:P1=1:P2=1
'save charge state stuff to log
  Open "solar.log" For Append As #1
  Print #1, Date$" "Time$"  "Format$(daywh(0),"%4.0f")"Wh In  "Format$(daywh(1),"%4.0f")"Wh Out "Format$(v,"%5.2f")"Batt V  "Format$(opi,"%5.2f")"Batt I  stat="status
  Close #1
 EndIf
'status mode is 2 standby
Else
'wait for a delay, then start sequence again.
 If Not rund Then
  status=1
  t2=0:t1=Timer+rundly
'If we are here because of an overload
  If overld>0 Then
   rund=False
  Else
   rund=True
  EndIf
 Else
'run inverter continuously as a sink if too much sun!
  If (v>overvolt Or (v>(overvolt-0.6) And invon<>0)) And overld=False Then
   Inc invon
   If opi>overload And t2>=wait4 Then Inc overld
  Else
   invon=False
  EndIf
 EndIf
EndIf
'Not mode 5 run fridges from mains after sun gone.
ElseIf status=5 Then
'turn off the inverter
invon=False
'run fridges every few hours
If mainsrun Then
'OFF toggle mode
 If rund Then
  If Not mainsoff Then
   mainsoff=True
  ElseIf mainsoff And (P1 Or P2) Then
'mains off, Fridges set to mains input(OFF)
   P1=0:P2=0
  Else
'default to mains input OFF, fridges set to mains input(OFF)
   P1=0:P2=0:mainsoff=True
  EndIf
'On toggle mode
 Else
  If mainsoff And Not(P1 And P2) Then
'inverter OFF, mains input OFF, Fridges set to inverter(OFF)
   P1=1:P2=1
  ElseIf mainsoff And P1 And P2 Then
'mains input ON, fridges set to inverter(OFF)
   mainsoff=False
  ElseIf Not mainsoff And P1 And P2 Then
'mains input On, fridges set to mains(ON)
   P1=0:P2=0
  Else
'Default to all runniing from mains input
   mainsoff=False:P1=0:P2=0
  EndIf
 EndIf
Else
'inverter OFF, mains OFF, Fridges set to mains(OFF)
 P1=0:P2=0:mainsoff=True
EndIf
'mode 3 Or 4
Else
' delay for a time before switching back to mains, allows compressor to de-compress.
If t2>wait4 And P1 And P2 Then mainsoff=False
If Not rund Then P1=0:P2=0
'So that the system starts initialised off
invon=False:relay=0

EndIf

If Not test Then
Pin(GP14)=invon>0  'inverter power on
Pin(GP15)=mainsoff 'remove mains power from outputs
Pin(GP16)=P1       'Power output 1 (either mains or inverter)
Pin(GP17)=P2       'Power output 2 (either mains or inverter)
'Power up and initialise the LCD
If hr=7 And lhr=6 Then
'only do once per day or when button pressed
  displ=True
ElseIf hr=20 And lhr=19 Then
'only do once per day Or when button pressed
  displ=False
EndIf
If displ And Not Pin(GP5) Then
 Pin(GP5)=1 'display backlight
 Pin(GP4)=1 'LCD module power
 Bitbang lcd init GP8,GP9,GP10,GP11,GP6,GP7
 Bitbang lcd Clear
ElseIf Not displ And Pin(GP5) Then
 Bitbang lcd Close
 Pin(GP5)=0 'display backlight
 Pin(GP4)=0 'LCD module power
EndIf
EndIf

If Test2 Then
Print Format$(ipi,"%4.2f")"A in  "Format$(opi,"%4.2f")"A out  "Format$(v,"%5.2f")"V  ";
Print Format$(wh(0),"%5.0f")"Wh in "Format$(wh(1),"%5.0f")"Wh out "Timer/sec"  "Time$
Print "invon="invon" P1="P1" P2="P2" relay="relay" mainsoff="mainsoff" stat="status
Print "charging="charging" overload="overld" alarm="alarm" t1="t1" t2="t2" rund="rund""
EndIf

'loop untill 1 second is up
Do While Timer<loopt
If Not Test Then
'is button pressed
 If Pin(GP0) Then
  Inc displc
'short press, turn on/off display
  If displc=2 Then displ=Not displ
'long press
  If displc=15 Then
'not currently in charge mode
   If charging=False Then
'initiate charge mode
    charging=True:status=3
    runon=tick:t2=0:t1=Timer+rundly:rund=True
    invon=False:P1=1:P2=1
'in charge mode
   Else
'turn off charge mode, run inverter for half an hour.
    charging=False:status=2:invon=False:P1=0:P2=0:relay=0
    runon=tick+overun*0.5:t2=0:t1=Timer+rundly:rund=True
   EndIf
  EndIf
 Else
  displc=0
 EndIf
EndIf
Pause 50
Loop

'add one second to timer, for the next loop.
Inc loopt,sec

'just after midnight to allow relays to all relax, so all power from mains
'internal clock corrections, save daily log then sleep for 6 hours
If hr=0 And t2=10 Then
Time$="00:00:09" 'just after midnight loose 2 seconds
'update Wh totals
Inc wkwh(0),daywh(0)
Inc wkwh(1),daywh(1)
Inc mtwh(0),daywh(0)
Inc mtwh(1),daywh(1)
Inc day

'save stuff to log
Open "solar.log" For Append As #1
If day=7 Or day=14 Or day=21 Then
 Print #1, Date$" D"Format$(daywh(0),"%4.0f")" W"Format$(wkwh(0),"%5.0f")" T"Format$(wh(0),"%6.0f")"Wh In  D"Format$(daywh(1),"%4.0f")" W"Format$(wkwh(1),"%5.0f")" T"Format$(wh(1),"%6.0f")"Wh Out  "Format$(v,"%5.2f")"V  stat="status
 VAR Save wkwh(),mtwh(),day
 wkwh(0)=0:wkwh(1)=0
ElseIf day>27 Then
 Print #1, Date$" W"Format$(wkwh(0),"%5.0f")" M"Format$(mtwh(0),"%6.0f")" T"Format$(wh(0),"%6.0f")"Wh In  W"Format$(wkwh(1),"%5.0f")" M"Format$(mtwh(1),"%6.0f")" T"Format$(wh(1),"%6.0f")"Wh Out  "Format$(v,"%5.2f")"V  stat="status
 day=0
 VAR Save wkwh(),mtwh(),day
 wkwh(0)=0:wkwh(1)=0
 mtwh(0)=0:mtwh(1)=0
Else
 Print #1, Date$" D"Format$(daywh(0),"%4.0f")" T"Format$(wh(0),"%6.0f")"Wh In  D"Format$(daywh(1),"%4.0f")" T"Format$(wh(1),"%6.0f")"Wh Out  "Format$(v,"%5.2f")"V  stat="status
 VAR Save wkwh(),mtwh(),day
EndIf
Close #1

daywh(0)=0:daywh(1)=0
WatchDog OFF
CPU SLEEP hr6
loopt=Timer+sec
EndIf

'update last hour to current
lhr=hr
'repeat whole program
Loop

'status=4 major fault
'disable all outputs, display error message.
Pin(GP14)=0
Pin(GP15)=0
Pin(GP16)=0
Pin(GP17)=0
If Not Pin(GP5) Then
Pin(GP5)=1 'display backlight
Pin(GP4)=1 'LCD module power
Bitbang lcd init GP8,GP9,GP10,GP11,GP6,GP7
Bitbang lcd Clear
EndIf
If MM.Watchdog Then
Bitbang lcd 1,1,"Program Halted  "
Else
Bitbang lcd 1,1,"Serious Fault   "
WatchDog OFF
EndIf
Bitbang lcd 2,1,"Check Log File  "
End

                                Batt -Ve                                
                                terminal
                                   ^
                     +----------+  |  +------------+
Solar Panel in>------+ 8A Shunt +->+>-+ 100A Shunt +-------->Power out
                     +----------+     +------------+
                      |        |       |          |
                     J22      J21     J32        J31