'step/dir_decoder_pico_PIO_version 4
 
 'program options
 do_assemble=0        'either assemble the code, or brute force program
 use_test_signal=1    'internally generate test signal
 
 'step pulse generation for testing
 if use_test_signal then
   stp_init             'init GPIO pins
   settick 10,do_step   '10ms = 100Hz step frequency
   cntr = 0            'step counter
   direction = 0       '0 = count up, 1 = count down  
 else
   setpin gp0,pio1    'the STEP signal
   setpin gp1,pio1    'the DIRECTION signal
 end if
 
 
 'Generic defines
 f= 63e6             '63 MHz PIO frequency
 pio clear 1
 dim dat%(4)         'array to store FIFO data
 
 
 ' PIO code -------------------------------------------------------------------
 
 if do_assemble then 'assemble
   
   'header and start of the PIO code
   pio assemble 1,".program test"
   pio assemble 1,".line 0"
   
   'wait for step pulse
   pio assemble 1,"wait 0,pin,0"  'wait for GP0 to become 0
   pio assemble 1,"wait 1,pin,0"  'wait for GP0 to become 1 = rising edge STEP pulse
   pio assemble 1,"JMP pin, plus1" 'jump according state GP1 pin
   
   'The plus and minus routines, X is the actual 32 bit position counter
   pio assemble 1,"minus1:"      'label:jump here to decrement X
   pio assemble 1,"JMP X--, push_out"  'decrement X
   pio assemble 1,"JMP push_out" 'regardless X value go to push_out
   pio assemble 1,"plus1:"       'label to increment X
   pio assemble 1,"mov X, !X"    'invert X
   pio assemble 1,"JMP X--, next1" 'decrement x
   pio assemble 1,"next1:"        'label:regardless X value come here
   pio assemble 1,"mov X, !X"     'invert back
   
   'send the most recent position to FIFO
   pio assemble 1,"push_out:"      'label
   pio assemble 1,"mov ISR, X"     'move X to ISR
   pio assemble 1,"push"           'push ISR into FIFO, not blocked
   
   'jump to start of PIO program
   pio assemble 1,"JMP 0"          'jump to beginning
   
   pio assemble 1,".end program"       '50900RC4 and newerr
   'pio assemble 1,".end program list" 'needed for 50900RC3
   
 else  'brute force program the same code
   
   dim p%(7)=(&h4800c520a02020,&ha0290047a0290008,&h8000a0c1,0,0,0,0,0)
   pio program 1,p%()
   
 end if
 
 
 'configure PIO 1 statemachine 0 (PIO 1 is free on PicoMiteVGA)
 p0=pio(pinctrl 0,0,0,gp0)           'gp0 is lowest IN pin (gp0,gp1)
 e0=pio(execctrl gp1,0,31)           'GP1=dir, wrap and wrap target
 s0=pio(shiftctrl 0,0,0,0,0,0)       'shift IN direction is left (the 5'th '0')
 
 
 'initialize PIO 1 state machine 0
 pio init machine 1,0,f,p0,e0,s0,0)  'init machine @ start loop
 
 
 'start the quadrature decoder PIO 1 statemachine 0
 pio start 1,0
 
 
 
 'main MMBasic code -------------------------------------------------------------
 
 'main loop
 do
   a$=inkey$                                     'just for control
   
   'get the data from the fifo
   pio read 1,0,5,dat%()                         'read whole fifo
   posi%=dat%(4)                                  'last data in fifo
   if posi%>2147483647 then inc posi%,-4294967296 '2'th complement
   print posi%                                    'show position
   
   'just some pause
   pause 100                                     'any delay needed
   
   'reset position (PIO X register) under control of keyboard
   if a$="r" then                                'press r to zero position
     pio execute 1,0,&hA023    '= assembly "mov X, null" (zero the X register)
     a$=""
   end if
   
   'set defined position in register X under control of the keyboard
   if a$="s" then
     input "desired count ";cnt%
     cnt%=cnt% and &hffffffff
     pio write 1,0,1,cnt%       'write the count cnt% in the fifo
     pio execute 1,0,&h8080  '= assemble "pull" (moves FIFO to OSR register)
     PIO execute 1,0,&hA027  '= assemble "mov X, OSR" moves the OSR value to X
     a$=""
   end if
   
 loop while a$=""  'exit when any key not r
 
end
 
 
 
 'test code in MMBasic that drives GP0 and GP1 according
sub stp_init
 setpin gp0,dout : pin(gp0)=0  'step pin
 setpin gp1,dout : pin(gp1)=0  'dir pin
end sub
 
sub do_step
 'this rountine counts 1000 steps up, then down, etc...
 inc cntr,1            'new step
 pulse gp0,0.1         '1 ms step pulse
 if cntr>=1000 then
   cntr = 0
   direction = 1 - direction
   pin(gp1) = direction
 end if
end sub

f= 63e6

print f

PIO init machine 1,0,f,p0,e0,s0,0)

PIO init machine 1,0,f,p0,e0,s0,0

> spi open 1000, 0, 16