'=============================================================================|
' PicoSpin
'
' written by Vegipete, Jan 2024
'
' needs:
' Firmware version 5.08.00 or newer
' OPTION CPUSPEED 252000 (KHz)

Option DEFAULT FLOAT 'INTEGER
Option LCDPANEL NOCONSOLE
Option angle degrees
CLS 0

Dim pln(9)=(8,5,4,16,8,8,12,4,8,12) ' length of each poly
' "PICOMITE" polygon definitions
' The "P" and the "O" require 2 parts each
Dim p0x(pln(0))=(-38,-38,-30,-28,-28,-30,-36,-36,-38)
Dim p0y(pln(0))=(5,-5,-5,-3,-1,1,1,5,5)
Dim p1x(pln(1))=(-36,-36,-31,-30,-31,-36)
Dim p1y(pln(1))=(-1,-3,-3,-2,-1,-1)
Dim p2x(pln(2))=(-27,-27,-25,-25,-27)
Dim p2y(pln(2))=(5,-5,-5,5,5)
Dim p3x(pln(3))=(2,0,0,2,8,10,8,7,3,2,2,3,7,8,10,8,2)
Math add p3x(),-23,p3x()  ' shift left into place
Dim p3y(pln(3))=(5,3,-3,-5,-5,-3,-2,-3,-3,-2,2,3,3,2,3,5,5)
Dim p4x(pln(4))=(-9,-11,-11,-9,-3,-1,-1,-3,-9)
Dim p4y(pln(4))=(5,3,-3,-5,-5,-3,3,5,5)
Dim p5x(pln(5))=(-8,-9,-9,-8,-4,-3,-3,-4,-8)
Dim p5y(pln(5))=(3,2,-2,-3,-3,-2,2,3,3)
Dim p6x(pln(6))=(1,1,3,7,11,13,13,11,11,7,3,3,1)
Dim p6y(pln(6))=(5,-5,-5,-1,-5,-5,5,5,-2,2,-2,5,5)
Dim p7x(pln(7))=(15,15,17,17,15)
Dim p7y(pln(7))=(5,-5,-5,5,5)
Dim p8x(pln(8))=(22,22,18,18,28,28,24,24,22)
Dim p8y(pln(8))=(5,-3,-3,-5,-5,-3,-3,5,5)
Dim p9x(pln(9))=(29,29,39,39,31,31,35,35,31,31,39,39,29)
Dim p9y(pln(9))=(5,-5,-5,-3,-3,-1,-1,1,1,3,3,5,5)

FRAMEBUFFER Create   ' hidden layer to draw scene
FRAMEBUFFER Write F : CLS 0

x = MM.HRes/2
y = MM.VRes/2
angl = 0
scal = 3
Do
 k = Asc(Inkey$)   ' press any key to quit
 If k Then
   FRAMEBUFFER Close
   End
 EndIf

 CLS
 For i = 0 To 9  ' draw all letter pieces
   DrawLetter(i,x,y,angl,pi*(Sin(scal)+1.1))
 Next
 FRAMEBUFFER copy F,N,B
 
 ' animate stuff
 ' could change position too, if you desire.
 Inc angl,.5
 Inc scal,.9
Loop

' polygon number,x,y,angle,scale
Sub DrawLetter(n,xc,yc,a,s)
 Local x(pln(n)),y(pln(n))
 
 Select Case n  ' scale copy polygon to working arrays
   Case 0
     Math scale p0x(),s,x() : Math scale p0y(),s,y()
   Case 1
     Math scale p1x(),s,x() : Math scale p1y(),s,y()
   Case 2
     Math scale p2x(),s,x() : Math scale p2y(),s,y()
   Case 3
     Math scale p3x(),s,x() : Math scale p3y(),s,y()
   Case 4
     Math scale p4x(),s,x() : Math scale p4y(),s,y()
   Case 5
     Math scale p5x(),s,x() : Math scale p5y(),s,y()
   Case 6
     Math scale p6x(),s,x() : Math scale p6y(),s,y()
   Case 7
     Math scale p7x(),s,x() : Math scale p7y(),s,y()
   Case 8
     Math scale p8x(),s,x() : Math scale p8y(),s,y()
   Case 9
     Math scale p9x(),s,x() : Math scale p9y(),s,y()
 End Select

 Math v_rotate 0,0,a,x(),y(),x(),y() ' spin 'em
 Math add x(),xc,x()   ' position 'em
 Math add y(),yc,y()
 Polygon pln(n),x(),y(),RGB(green) ' draw em (b/w in Mode 1)
 ' Note: fill mode bogs down above a certain size
End Sub

BOX 0,0,mm.hres,mm.vres,1,0