POLYGON n, xarray%(),yarray%() [, bordercolour] [,fillcolour]

' 2D Command Demo
' by Vegipete, Jan 2024

mode 2 ' otherwise FRAMEBUFFER LAYER doesn't work
Option DEFAULT INTEGER
Option LCDPANEL NOCONSOLE
Option angle degrees

Const NUMSIDES = 7

dim desc$(10) length 50
desc$(1) = "A regular polygon"
desc$(2) = "Same polygon, draw vertices only"
desc$(3) = "Draw circles at the vertices"
desc$(4) = "Lines from the vertices"
desc$(5) = "Polygon and lines"
desc$(6) = ""
Dim float vert(NUMSIDES-1,1), v1(NUMSIDES-1,1)
Dim float ang

CLS 0
FRAMEBUFFER Layer
FRAMEBUFFER Write L : CLS 0

' Generate a regular polygon
r = 25 : ang = 360/NUMSIDES
For i=0 To NUMSIDES-1:vert(i,0)=r*Sin(i*ang):vert(i,1)=r*Cos(i*ang):Next

for i = 1 to 5
 FRAMEBUFFER Write L : CLS 0
 text 20,20,desc$(i)
 FRAMEBUFFER Write N
 PerformStuff(vert(),i)
 Pause 1000
next
FRAMEBUFFER close
end

Sub PerformStuff(vert() As Float,d)
 Local i,n = Bound(vert())
 Local float v1(n,1)   ' local working copy of vertex cloud
 Local float v2(n,1)

 For i=1 To 100
   Math Scale vert(),1,v1()      ' copy to working
   Math2DArrayScale(v1(),i/20,i/20)   ' scale copy of vertex cloud
   Math2DArrayRotate(v1(),i*3.6) ' rotate it
   Math2DArrayAdd(v1(),MM.HRes/2,MM.VRes/2)    ' translate it
   
   CLS
   Select Case d
     Case 1
       Polygon2d(NUMSIDES,v1(),RGB(white),RGB(black))
     Case 2
       Pixel2d(v1(),RGB(white))
     Case 3
       Circle2d(v1(),1+i/2,RGB(white))
     Case 4
       Math Set 0,v2()
       Math2DArrayAdd(v2(),MM.HRes/2+(i-50)*4,MM.VRes/2)
       Line2d(v1(),v2(),RGB(white))
     Case 5
       Math Set 0,v2()
       Math2DArrayAdd(v2(),MM.HRes/2+(i-50)*4,MM.VRes/2)
       Line2d(v1(),v2(),RGB(white))
       Polygon2d(NUMSIDES,v1(),RGB(white),RGB(black))
   End Select
   Pause 50
 Next

End Sub

' Drawing routines similar to firmware but accept 2D array
'
' Draw a polygon using data from a 2D array
Sub Polygon2d(n,coor() As Float,c1,c2)
 Local float x(n-1),y(n-1)
 Math slice coor(),,0,x()  ' yank out x axis data
 Math slice coor(),,1,y()  '  and y axis data
 Polygon n,x(),y(),c1      ' use built in function
End Sub

' Draw a pixel cloud using data from a 2D array
Sub Pixel2d(coor() As Float,c1)
 Local n = Bound(coor())
 Local float x(n),y(n)
 Math slice coor(),,0,x()  ' yank out x axis data
 Math slice coor(),,1,y()  '  and y axis data
 Pixel x(),y(),c1      ' use built in function
End Sub

' Draw a circle cloud using data from a 2D array
Sub Circle2d(coor() As Float,r As Float,c1)
 Local n = Bound(coor())
 Local float x(n),y(n),rs(n)
 Math slice coor(),,0,x()  ' yank out x axis data
 Math slice coor(),,1,y()  '  and y axis data
 Math set r,rs()           ' all radii the same
 Circle x(),y(),rs(),,,c1      ' use built in function
End Sub

' Draw a line cloud using data from a pair of 2D arrays
Sub Line2d(b() As Float,e() As Float,c1)
 Local n = Bound(b())
 Local float x1(n),y1(n),x2(n),y2(n)
 Math slice b(),,0,x1()
 Math slice b(),,1,y1()
 Math slice e(),,0,x2()
 Math slice e(),,1,y2()
 Line x1(),y1(),x2(),y2(),,c1  ' use built in function
End Sub

' Math functions that manipulate 2D arrays as coordinates
'
' Scale array, x and y scaling factors can be different
Sub Math2DArrayScale(arry() As float,x As float,y As float)
 Local n = Bound(arry())
 Local float t(n)
 Math slice arry(),,0,t()
 Math scale t(),x,t()
 Math insert arry(),,0,t()
 Math slice arry(),,1,t()
 Math scale t(),y,t()
 Math insert arry(),,1,t()
End Sub

' Translate array
Sub Math2DArrayAdd(arry() As float,x As float,y As float)
 Local n = Bound(arry())
 Local float t(n)
 Math slice arry(),,0,t()
 Math add t(),x,t()
 Math insert arry(),,0,t()
 Math slice arry(),,1,t()
 Math add t(),y,t()
 Math insert arry(),,1,t()
End Sub

' Rotate coordinate pairs in array
Sub Math2DArrayRotate(arry() As float,ang As float)
 Local i,n
 Local float tmp,sa,ca

 n = Bound(arry())
 sa = Sin(ang) : ca = Cos(ang)
 For i = 0 To n
   tmp = arry(i,0)
   arry(i,0) = tmp * ca - arry(i,1) * sa
   arry(i,1) = tmp * sa + arry(i,1) * ca
 Next
End Sub

Pixel array(,0),array(,1),col