'Based on Conway's Game of Life - PicoMiteVGA

'Grid Size
MODE 1
Const WIDTH = 340
Const HEIGHT =200
Const CELL = 10
Gens = 0
CLS

FRAMEBUFFER CREATE


createSprites()
'Create some sprites to copy for the cells


'set up inital screen
FRAMEBUFFER WRITE F

For x = 10 To WIDTH Step CELL
 For y = 10 To HEIGHT Step CELL
   alive = Int(Rnd*2)
   If alive = 1 Then
     Sprite WRITE 1,x, y
   EndIf
 Next
Next

FRAMEBUFFER COPY f,n

'main loop
Do
gens = gens + 1
If gens = 101 Then Run
'clear out the next screen
FRAMEBUFFER write f
CLS

Colour RGB(white)
Text 0,260, "Generation " +Str$(gens)
Colour RGB(black)

For x = 10 To WIDTH Step CELL
 For y = 10 To HEIGHT Step CELL
   FRAMEBUFFER write n  'count neighbours on current
   aliveNeighbours = countNeighbours(x,y)
   pixCol = Pixel(x+5,y+5) 'move to cell centre

   FRAMEBUFFER write f  'move back to new screen for all updates
   If pixCol = 16777215 Then

     If aliveNeighbours <2 Or aliveNeighbours > 3 Then
       Sprite write 2,x,y
     Else

       Sprite write 1,x,y
     EndIf
   Else
     If aliveNeighbours = 3 Then

       Sprite write 1,x,y
     EndIf
   EndIf
   'spontaneous creation and dying - added to allow sim to run longer

   mutate =Rnd()
   If mutate < 0.01 Then
     Sprite write 2,x,y  'spontaneous death
   ElseIf mutate > 0.999 Then
     Sprite write 1,x,y  'spontaneous life
   EndIf

 Next y
Next x


FRAMEBUFFER copy f,n

Loop



Function countNeighbours(x,y)
 count = 0
 For dx = -10 To 10 Step CELL
   For dy = -10 To 10 Step CELL
     If (dx= 0 And dy=0) Then
     ' dont count yourself
     Else
         nx = (x+dx+WIDTH) Mod WIDTH
         ny = (y+dy+HEIGHT) Mod HEIGHT
         pixCol = Pixel(nx+5,ny+5)
         If pixCol = 16777215 Then
           count = count + 1
         EndIf
     EndIf
   Next dy
 Next dx
 countNeighbours = count
End Function



Sub createSprites()
 Colour RGB(black)
 Circle 10,10,5,,,,RGB(white)
 Sprite read 1, 5,5,15,15

 Colour RGB(black)
 Circle 10,10,5,,,,RGB(black)
 Sprite read 2, 5,5,15,15
End Sub

SD Card pins (bottom view)
nc CS MOSI ⏚  3V3 SCK  ⏚ MISO nc
  _______________________________
 / 1   2   3   4   5   6   7   8 |
/9 CS MOSI ⏚  3V3 SCK  ⏚ MISO nc|
|nc                              |
|                                |