#include <EEPROM.h>
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
#include <time.h>  // NTP time library

// EEPROM Addresses for storing data
const int EEPROM_SIZE = 10;  // Enough space for 4 integers (start hour, start minute, start second, and duration)

// WiFi credentials
const char* ssid = "Removed";
const char* password = "Removed";

IPAddress local_IP(192, 168, 178, 50);  // Set your desired IP address here
IPAddress gateway(192, 168, 178, 1);     // Set your gateway (usually the router's IP)
IPAddress subnet(255, 255, 255, 0);    // Subnet mask
IPAddress dns(192, 168, 178, 1);  

// NTP Server
const char* ntpServer = "pool.ntp.org";
const long gmtOffset_sec = 36000;    // Set to your time zone's GMT offset (in seconds)
const int daylightOffset_sec = 0; // Set to 0 if no daylight savings

// Pin configuration
const int relayPin = 0;  // GPIO0 for relay control

// Web server running on port 80
ESP8266WebServer server(80);

// Variables to store relay control time and duration
int startHour1 = 0, startMinute1 = 0, startSecond = 0;
int startHour2 = 0, startMinute2 = 0;
int durationSeconds = 5;
bool relayOn = false;
bool manualTest = false;  // Flag for manual test

void setup() {
 Serial.begin(115200);
 pinMode(relayPin, OUTPUT);
 digitalWrite(relayPin, HIGH);  // Relay off by default
 
 EEPROM.begin(EEPROM_SIZE);
 loadTimerSettings();  // Load saved timer settings from EEPROM

 // Connect to WiFi
 if (!WiFi.config(local_IP, gateway, subnet, dns)) {
   Serial.println("Failed to configure Static IP");
 }

 WiFi.begin(ssid, password);
 WiFi.hostname("CatFeeder");
 Serial.print("Connecting to WiFi");
 while (WiFi.status() != WL_CONNECTED) {
   delay(500);
   Serial.print(".");
 }
 Serial.println("\nConnected to WiFi!");
 Serial.print("IP address: ");
 Serial.println(WiFi.localIP());
 Serial.print("Hostname: ");
 Serial.println(WiFi.hostname());

 // Initialize NTP
 configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);

 server.on("/", handleRoot);
 server.on("/setTime", handleSetTime);
 server.on("/manualTest", handleManualTest);  // Manual test button
 
 server.begin();
 Serial.println("Web server started.");
}

void loop() {
 server.handleClient();

 // Get the current time
 time_t now = time(nullptr);
 struct tm* currentTime = localtime(&now);

 int currentHour = currentTime->tm_hour;
 int currentMinute = currentTime->tm_min;
 int currentSecond = currentTime->tm_sec;

 // Check if the relay should be on
 if (((currentHour == startHour1 && currentMinute == startMinute1 && currentSecond == 0) || (currentHour == startHour2 && currentMinute == startMinute2 && currentSecond == 0)) && !relayOn && !manualTest) {
   digitalWrite(relayPin, LOW);  // Turn on the relay
   relayOn = true;
   startSecond=currentSecond;
   Serial.println("Relay turned on!");
 }
 
 // Turn off the relay after the specified duration
 if (relayOn && (currentSecond - startSecond) >= durationSeconds ) {
   digitalWrite(relayPin, HIGH);  // Turn off the relay
   relayOn = false;
   manualTest = false;  // Reset manual test flag after operation
   Serial.println("Relay turned off!");
 }
}

void loadTimerSettings() {
 startHour1 = EEPROM.read(0);
 startMinute1 = EEPROM.read(1);
 startHour2 = EEPROM.read(2);
 startMinute2 = EEPROM.read(3);
 durationSeconds = EEPROM.read(4) | (EEPROM.read(5) << 8);  // Combine the two bytes of duration
 Serial.println("Timer settings loaded from EEPROM.");
}

void saveTimerSettings() {
 EEPROM.write(0, startHour1);
 EEPROM.write(1, startMinute1);
 EEPROM.write(2, startHour2);
 EEPROM.write(3, startMinute2);
 EEPROM.write(4, durationSeconds & 0xFF);         // Lower byte of duration
 EEPROM.write(5, (durationSeconds >> 8) & 0xFF);  // Higher byte of duration
 EEPROM.commit();
 Serial.println("Timer settings saved to EEPROM.");
}

void handleRoot() {
 time_t now = time(nullptr);
 struct tm* currentTime = localtime(&now);

 // Format current time as HH:MM:SS
 String currentTimeStr = String(currentTime->tm_hour) + ":" +
                         String(currentTime->tm_min) + ":" +
                         String(currentTime->tm_sec);

 // Format scheduled time for the relay as HH:MM:SS
 String scheduledTimeStr1 = String(startHour1) + ":" + String(startMinute1) + ":00";
 String scheduledTimeStr2 = String(startHour2) + ":" + String(startMinute2) + ":00";

 // HTML content
 String html = "<html><body><h1>Alf Feeder</h1><hr/>";
 html += "<p>Current Time: " + currentTimeStr + "</p>";
 html += "<p>Feed Scheduled Time 1 : " + scheduledTimeStr1 + "</p>";
 html += "<p>Feed Scheduled Time 2 : " + scheduledTimeStr2 + "</p>";
 html += "<p>Relay Duration: " + String(durationSeconds) + " seconds</p>";
 
 html += "<fieldset><legend>Settings</legend><form action=\"/setTime\" method=\"GET\">";
 html += "Feed Time 1: <input type=\"number\" name=\"hour1\" min=\"0\" max=\"23\" value=\"" + String(startHour1) +"\">H : <input type=\"number\" name=\"minute1\" min=\"0\" max=\"59\" value=\"" + String(startMinute1) +"\">M<br>";
 html += "Feed Time 2: <input type=\"number\" name=\"hour2\" min=\"0\" max=\"23\" value=\"" + String(startHour2) +"\">H : <input type=\"number\" name=\"minute2\" min=\"0\" max=\"59\" value=\"" + String(startMinute2) +"\">M<br>";
 html += "Duration (seconds): <input type=\"number\" name=\"duration\" min=\"0\" max=\"3600\" value=\"" + String(durationSeconds) + "\"><br>";
 html += "<input type=\"submit\" value=\"Set Time\">";
 html += "</form></fieldset>";
 
 html += "<form action=\"/manualTest\" method=\"GET\">";
 html += "<input type=\"submit\" value=\"Test Relay\">";
 html += "</form>";
 
 html += "</body></html>";
 server.send(200, "text/html", html);
}
// Handle setTime page
void handleSetTime() {
 if (server.hasArg("hour1") && server.hasArg("minute1") && server.hasArg("hour2") && server.hasArg("minute2")  && server.hasArg("duration")) {
   startHour1 = server.arg("hour1").toInt();
   startMinute1 = server.arg("minute1").toInt();
   
   startHour2 = server.arg("hour2").toInt();
   startMinute2 = server.arg("minute2").toInt();
   durationSeconds = server.arg("duration").toInt();
   saveTimerSettings();
   server.send(200, "text/html", "Time set! Go <a href=\"/\">back</a>.");
   Serial.print("Time 1 set to: ");
   Serial.print(startHour1);
   Serial.print(":");
   Serial.print(startMinute1);
   Serial.print(" Time 2 set to: ");
   Serial.print(startHour2);
   Serial.print(":");
   Serial.print(startMinute2);


   Serial.print(" for ");
   Serial.print(durationSeconds);
   Serial.println(" seconds.");
 } else {
   server.send(400, "text/html", "Invalid request.");
 }
}

// Handle manual test button
void handleManualTest() {
 if (!relayOn) {
   digitalWrite(relayPin, LOW);  // Turn on the relay
   relayOn = true;
   manualTest = true;  // Set manual test flag
   startSecond = second();
    // Start the manual timer
   server.send(200, "text/html", "Manual test activated! Relay on for set duration. Go <a href=\"/\">back</a>.");
   Serial.println("Manual test: Relay turned on!");
 } else {
   server.send(200, "text/html", "Relay already active. Go <a href=\"/\">back</a>.");
 }
}

int second() {
 time_t now = time(nullptr);
 struct tm* currentTime = localtime(&now);
 return currentTime->tm_sec;
}