'The Power of 16 Colors

'PicoMiteHDMI only - MMBasic Version 6.00.00b8 or higher

'Reads and shows 4 Bit uncompressed BMP Files in up to 640x480 resolution
' and sets the Colors using the new MAP Command
MODE 2
Map reset:Map set
CLS
Dim integer w,h,f,cl,c
Do
 MODE 2
 Read File$:If file$="end" Then Restore :Read file$
 Open file$ For random As #1
 read_BMP_Header
 Map set
 If h>240 Then MODE 3
 hi=MM.VRes
 yofs=(hi-h)/2
 yofs=hi-yofs
 Seek #1,of+1'54+65
 For y=yofs To yofs-h-2 Step -1
   For x=0 To w-1 Step 2
     l$=Input$(1,1):cl=Asc(l$)
     Pixel x,y,Map(cl>>4):Pixel x+1,y,Map(cl And 15)
   Next
 Next
 Close #1
 'display the used colors
 For c=0 To 15:cl=Map(c):Box c*20,0,20,10,,cl,cl:Next
 Pause 2000
Loop
Data "chess.bmp","wasserfall2-4.bmp","waterfall.bmp","ST_Graph.bmp","outrun_a.b
mp"
Data "end"
Sub read_BMP_Header
Local l$
WStart= &H13
Hstart= &H17
MPStart= 55
'read offset of Picture data
Seek #1,11
l$=Input$(1,1):of=Asc(l$)
l$=Input$(1,1):Inc of,256*(Asc(l$))
'read Picture width
Seek #1,WStart
l$=Input$(1,1):W=Asc(l$)
l$=Input$(1,1):Inc w,256*(Asc(l$))
'read Picture height
Seek #1,HStart
l$=Input$(1,1):h=Asc(l$)
l$=Input$(1,1):Inc h,256*(Asc(l$))
'convert the Color data to Map
Seek #1,MPStart
For F=0 To 15
l$=Input$(1,1):B=Asc(l$)
l$=Input$(1,1):G=Asc(l$)
l$=Input$(1,1):R=Asc(l$)
l$=Input$(1,1)'fillbyte
   Map(f)=RGB(R,G,B)
Next
End Sub