ADC open samrate, channum, _sam_ready() ' Setup the channel for capture
ADC start afcap_0() ' Start capturing into bufnum 0

Math scale afcap_0(),77,afcap_scaled()  ' 77 =~ 255/3.3 as integer

For idx = 1 To sambufsize
 Inc writebufstr,Bin2str$(uint8,afcap_scaled(idx)) ' Exiting edit converts CAT to INC
Next idx
Print #1; writebufstr

' adc2wav v19 drops samples over about 6kHz samrate
' by Leo Edmiston-Cyr <leoec@gopher.quest>
' Last updated: 11/11/2023
'
Option explicit ' require explicit variable declaration

Dim samdelay = 0        ' duration to delay before recording
Dim samduration = 30    ' duration of recording in seconds
Dim sambufsize = 255   ' string limit -- buffer size for recrd/writing to file
Dim samrate = 10000      ' samples per second (Hz)
Dim samnum = samduration * samrate  ' total samples in recording
Dim integer samrepeat = Fix(samnum /sambufsize)  ' number sambufsize ADC cycles

Dim string filename = mm.cmdline$
If filename = "" Then
 filename = "adc2wav-" + Date$ + Str$(Epoch(now)) + ".wav"
EndIf

'
' RIFF WAVE format metadata
' samnum <-from above
Dim samsize = 1 ' bytes per sample
Dim channum = 1 ' 1 = Mono; 2 = Stereo
' samrate <-from above
'compute chunk size
'Dim integer chunksize = 32 + samnum * samsize * samrepeat ' num samples *
Dim integer chunksize = 32 + samnum * samsize ' num samples *
Dim integer subChunkSize = 16
Dim integer byterate = samrate * channum * samsize
Dim integer sambits = samsize*8 '8 bits per byte; obs

Dim integer idx ' When you need a loop index counter...  Just in case ;)

' Hi user, here's what's going on
Print "Recording to:",filename
Print "duration:",samduration
Print "channel(s):",channum
Print "bit depth:",samsize*8;"bits"
Print "sample rate:",samrate;"Hz"
Print "buffer size:",sambufsize;"byte(s)"
Print "buffer writes:",samrepeat
Print "total samples:",samnum

'
' write WAVE file format for later .wav playback
Open filename For output As #1

'The following metadata satisfies the RIFF WAVE format requirements
Print #1; "RIFF";
Print #1; Bin2str$(UINT32,chunksize);
Print #1; "WAVE";
Print #1; "fmt ";

' SubChunk
Print #1; Bin2str$(UINT32,subChunkSize);  ' the size of this sub chunkfor PCM
Print #1; Bin2str$(UINT16, 1); ' Audio format PCM = 1 is linear quantization
Print #1; Bin2str$(UINT16, channum); ' number of channels 2 = stereo
Print #1; Bin2str$(UINT32, samrate);  ' sample rate 8000, 44100, etc.
Print #1; Bin2str$(UINT32, byterate);
Print #1; Bin2str$(UINT16, channum * samsize); ' block align-bytes for one sample of all channels
Print #1; Bin2str$(UINT16, sambits);  ' bits per sample

' ExtraParams -- none for PCM encoding
'   ExtraParamSize -- doesn't exist for PCM
'   ExtraParams

Print #1; "data";  ' Subchunk2ID
' RIFF WAVE metadata is complete

Dim float afcap_0(sambufsize) ' required destination for ADC start
Dim float afcap_1(sambufsize) ' used with _a in a sampling-writing sequence
Dim integer afcap_scaled(sambufsize) ' destination for MATH SCALE

Dim integer samp
Dim integer samrunning = 0
Dim integer repeatcount = 0
Dim integer samready = 0        ' Flag for ADC completion when the sample is ready
Dim integer samwritten = 1      ' flag if writing has completed
Dim integer intsmissed = 0      ' count of missed interrupts


' Initiate sampling of the audio input
SetPin gp26, ain  ' set ADC input
ADC open samrate, channum, _sam_ready() ' Setup the channel for capture
ADC start afcap_0() ' Start capturing into bufnum 0
Dim bufnum = 0  ' which buffer is being sampled into?
Dim string writebufstr ' 255 byte buffer to write samples in blocks

Do
 If samready = 1 Then
   samready = 0
   writebufstr = ""  ' clear write buffer
   'For idx = 1 To sambufsize
   '  Print #1; Bin2str$(uint8,afcap_scaled(idx));
   'Next idx

   ' I write CAT, save, open, I see Inc instead
   For idx = 1 To sambufsize
     Inc writebufstr,Bin2str$(uint8,afcap_scaled(idx))
   Next idx
   Print #1; writebufstr
 EndIf

 If repeatcount = samrepeat Then Exit  ' Have all the samples been captured?
Loop

Print "recording complete."

Close #1
ADC close


'''''''''''''''''''''''''''''''''''''''
'sub pattern reference
 'sub mysub arg1, arg2$, arg3
 'end sub
'NOTE: No parameters can be passed to an interrupt handler subroutine

'''''''''''''''''''''''''''''''''''''''


''''''''''''''''''''''''''''''''''''''''
' Interrupt handling with flip-flop buffers for "ADC open <subname>"

'''''''''''''''''''''''''''''''''''''''
Sub _sam_ready()
 If repeatcount = samrepeat Then End  ' End if all samples are captured

 ' this is the only place where knowledge of the active buffer is needed
 If bufnum = 0 Then
     ' If bufnum 0 is full, start next capture into bufnum 1; scale for write
     ADC start afcap_1()
     Math scale afcap_0(),77,afcap_scaled()  ' 77 =~ 255/3.3 as integer
     bufnum = 1
 Else
     ' bufnum 1 is full, start capture into 0 and scale for write
     ADC start afcap_0()
     Math scale afcap_1(),77,afcap_scaled()  ' 77 =~ 255/3.3 as integer
     bufnum = 0
 EndIf

 samrunning = 1
 Inc repeatcount

 samready = 1
 samrunning = 0
End Sub

Option explicit
Option default integer
Const buffsize = 1000 '4000 samples
Const nsamples = buffsize * 4
Dim a(buffsize-1),b(buffsize-1),d(nsamples-1)

' print the wav header to the file here

ADC open 20000,1,myint 'one channel, sampled at 20000Hz"
Dim i,j,k,c=0, count=0
Dim s$
Open "B:/data.wav" For output As #1
ADC run a(),b()
Do
Loop Until c 'wait for the first conversion to complete
Do
   If c=1 Then
     Memory unpack a(),d(), nsamples, 16
   Else
     Memory unpack a(),d(), nsamples, 16
   EndIf
   Math scale d(),16,d() 'was 0-4095 scale to 0 to 65520
   i=0
   Do While i<buffsize
       s$=""
       j=Min(50,nsamples-i)
       For k=0 To j-1
           Inc s$,Bin2str$(uint16,d(i+k))
       Next
       Inc i,j
       Print #1,s$
       If j<>50 Then Print j
   Loop
   Inc count
   Print c;
   Timer =0
   c=0
   Do :Loop Until c
   Print Timer 'see how much time we have left before we need to process again
Loop Until count=100 ' arbitrary duration
Close #1
'
Sub myint
 c= MM.Info(ADC)
End Sub

OPTION SYSTEM SPI GP10,GP11,GP12
OPTION COLOURCODE ON
OPTION CPUSPEED  252000 'KHz
OPTION SDCARD GP15
OPTION AUDIO VS1053 GP2,GP3,GP4,GP5,GP6,GP7,GP8', ON PWM CHANNEL 1

  If c=1 Then
    Memory unpack a(),d(), nsamples, 16
  Else
    Memory unpack b(),d(), nsamples, 16
  EndIf

Option explicit
Option default integer
Const buffsize = 1000 '4000 samples
Const nsamples = buffsize * 4
const nbytes = buffsize * 8
Dim a(buffsize-1),b(buffsize-1)
ADC open 20000,1,myint 'one channel, sampled at 20000Hz"
Dim c=0, count=0
Dim s$
Open "B:/data.wav" For output As #1

' print the wav header to the file here

ADC run a(),b()
Do
Loop Until c 'wait for the first conversion to complete
Do
  If c=1 Then
     Math shift a(),4,a() ' shift all array elements 4 bits left =  multiply by 16
     Memory print #1,nbytes,a() 'print array direct to disk
  Else
     Math shift b(),4,b()
     Memory print #1,nbytes,b()
  EndIf
  Print c;
  Timer =0
  c=0
  Do :Loop Until c
  Print Timer 'see how much time we have left before we need to process again
  Inc count
Loop Until count=100 ' arbitrary duration
Close #1
'
Sub myint
c= MM.Info(ADC)
End Sub

' adc2wav v23 includes pmather ADC routines
' by Leo Edmiston-Cyr <leoec@gopher.quest>
' Last updated: 11/20/2023
'
Option explicit
Option default integer
Dim c=0, count=0

' print the wav header to the file here

Dim samdelay = 0          ' duration to delay before recording
Dim samduration = 10      ' duration of recording in seconds
Const sambufsize = 1000   ' 4000 16 bit samples; 12 bit resolution

Const sams_in_buf = sambufsize * 4    ' 4 16 bit samples per int
Const nbytes = sambufsize * 8         ' 8 bytes per int
Dim samrate = 20000                   ' samples per second (Hz)
Const samnum = samduration * samrate  ' total samples in recording
Const samrepeat = samnum / sams_in_buf  ' num sambufsize ADC cycles

Dim string filename = mm.cmdline$
If filename = "" Then
 filename = "adc2wav-" + Date$ + Str$(Epoch(now)) + ".wav"
EndIf

Dim samsize = 2 ' bytes per sample
Dim channum = 1 ' 1 = Mono; 2 = Stereo
Dim chunksize = 32 + samnum * samsize ' num samples *
Dim subChunkSize = 16
Dim byterate = samrate * channum * samsize
Dim sambits = samsize * 8 '8 bits per byte; obs
Dim afcap_0(sambufsize-1), afcap_1(sambufsize-1)

' Hi user, here's what's going on
Print "Recording to:",filename
Print "duration:",samduration
Print "channel(s):",channum
Print "bit depth:",samsize*8;"bits"
Print "sample rate:",samrate;"Hz"
Print "buffer size:",sambufsize;"byte(s)"
Print "buffer writes:",samrepeat
Print "total samples:",samnum

'
' write WAVE file format for later .wav playback
Open filename For output As #1

'The following metadata satisfies the RIFF WAVE format requirements
Print #1; "RIFF";
Print #1; Bin2str$(UINT32,chunksize);
Print #1; "WAVE";
Print #1; "fmt ";

' SubChunk
Print #1; Bin2str$(UINT32,subChunkSize);  ' the size of this sub chunkfor PCM
Print #1; Bin2str$(UINT16, 1); ' Audio format PCM = 1 is linear quantization
Print #1; Bin2str$(UINT16, channum); ' number of channels 2 = stereo
Print #1; Bin2str$(UINT32, samrate);  ' sample rate 8000, 44100, etc.
Print #1; Bin2str$(UINT32, byterate);
Print #1; Bin2str$(UINT16, channum * samsize); ' block align-bytes for one sample of all channels
Print #1; Bin2str$(UINT16, sambits);  ' bits per sample

' ExtraParams -- none for PCM encoding
'   ExtraParamSize -- doesn't exist for PCM
'   ExtraParams

Print #1; "data";  ' Subchunk2ID
' RIFF WAVE metadata is complete

' Initiate sampling of the audio input
'''''''''''''''''''''''''''''''''''''''
ADC open samrate,channum,myint
ADC run afcap_0(),afcap_1()

Do
Loop Until c 'wait for the first conversion to complete

Do
 If c=1 Then
    Math shift afcap_0(),4,afcap_0() ' shift all array elements 4 bits left =  multiply by 16
    Memory print #1,nbytes,afcap_0() 'print array direct to disk
 Else
    Math shift afcap_1(),4,afcap_1()
    Memory print #1,nbytes,afcap_1()
 EndIf
 'Print c;
 Timer =0
 c=0
 Do :Loop Until c
 'Print Timer 'time remaining before next sample is ready to write
 Inc count
Loop Until count=samrepeat ' arbitrary duration

Close #1
Print "recording complete."
ADC close

Sub myint
c= MM.Info(ADC)
End Sub